1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
|
include(qpdfview.pri)
TARGET = qpdfview
TEMPLATE = app
OBJECTS_DIR = objects
MOC_DIR = moc
HEADERS += \
sources/global.h \
sources/model.h \
sources/pageitem.h \
sources/searchthread.h \
sources/presentationview.h \
sources/printoptions.h \
sources/documentview.h \
sources/printoptionswidget.h \
sources/miscellaneous.h \
sources/settings.h \
sources/settingsdialog.h \
sources/recentlyusedmenu.h \
sources/bookmarkmenu.h \
sources/mainwindow.h
SOURCES += \
sources/model.cpp \
sources/pageitem.cpp \
sources/searchthread.cpp \
sources/presentationview.cpp \
sources/documentview.cpp \
sources/printoptionswidget.cpp \
sources/miscellaneous.cpp \
sources/settings.cpp \
sources/settingsdialog.cpp \
sources/recentlyusedmenu.cpp \
sources/bookmarkmenu.cpp \
sources/mainwindow.cpp \
sources/main.cpp
QT += core gui
greaterThan(QT_MAJOR_VERSION, 4): QT += concurrent widgets printsupport
!without_svg {
DEFINES += WITH_SVG
QT += svg
RESOURCES += qpdfview.qrc
}
!without_sql {
DEFINES += WITH_SQL
QT += sql
}
!without_dbus {
DEFINES += WITH_DBUS
QT += dbus
}
DEFINES += PLUGIN_INSTALL_PATH=\\\"$${PLUGIN_INSTALL_PATH}\\\"
!without_pdf {
DEFINES += WITH_PDF
static_pdf_plugin {
isEmpty(PDF_PLUGIN_NAME):PDF_PLUGIN_NAME = libqpdfview_pdf.a
DEFINES += STATIC_PDF_PLUGIN
LIBS += $$PDF_PLUGIN_NAME
PRE_TARGETDEPS += $$PDF_PLUGIN_NAME
QT += xml
!without_pkgconfig {
CONFIG += link_pkgconfig
PKGCONFIG += poppler-qt4
}
} else {
isEmpty(PDF_PLUGIN_NAME):PDF_PLUGIN_NAME = libqpdfview_pdf.so
}
DEFINES += PDF_PLUGIN_NAME=\\\"$${PDF_PLUGIN_NAME}\\\"
}
!without_ps {
DEFINES += WITH_PS
static_ps_plugin {
isEmpty(PS_PLUGIN_NAME):PS_PLUGIN_NAME = libqpdfview_ps.a
DEFINES += STATIC_PS_PLUGIN
LIBS += $$PS_PLUGIN_NAME
PRE_TARGETDEPS += $$PS_PLUGIN_NAME
!without_pkgconfig {
CONFIG += link_pkgconfig
PKGCONFIG += libspectre
}
} else {
isEmpty(PS_PLUGIN_NAME):PS_PLUGIN_NAME = libqpdfview_ps.so
}
DEFINES += PS_PLUGIN_NAME=\\\"$${PS_PLUGIN_NAME}\\\"
}
!without_djvu {
DEFINES += WITH_DJVU
static_djvu_plugin {
isEmpty(DJVU_PLUGIN_NAME):DJVU_PLUGIN_NAME = libqpdfview_djvu.a
DEFINES += STATIC_DJVU_PLUGIN
LIBS += $$DJVU_PLUGIN_NAME
PRE_TARGETDEPS += $$DJVU_PLUGIN_NAME
!without_pkgconfig {
CONFIG += link_pkgconfig
PKGCONFIG += ddjvuapi
}
} else {
isEmpty(DJVU_PLUGIN_NAME):DJVU_PLUGIN_NAME = libqpdfview_djvu.so
}
DEFINES += DJVU_PLUGIN_NAME=\\\"$${DJVU_PLUGIN_NAME}\\\"
}
!without_cups {
DEFINES += WITH_CUPS
LIBS += $$system(cups-config --libs)
}
!without_synctex {
DEFINES += WITH_SYNCTEX
LIBS += -lz
INCLUDEPATH += synctex
SOURCES += synctex/synctex_parser.c synctex/synctex_parser_utils.c
}
!without_signals {
DEFINES += WITH_SIGNALS
HEADERS += sources/signalhandler.h
SOURCES += sources/signalhandler.cpp
}
target.path = $${TARGET_INSTALL_PATH}
data.files = icons/qpdfview.svg translations/*.qm miscellaneous/help.html
data.path = $${DATA_INSTALL_PATH}
DEFINES += DATA_INSTALL_PATH=\\\"$${DATA_INSTALL_PATH}\\\"
launcher.files = miscellaneous/qpdfview.desktop
launcher.path = $${LAUNCHER_INSTALL_PATH}
system(sed \"s/DATA_INSTALL_PATH/$$replace(DATA_INSTALL_PATH, "/", "\\/")/\" miscellaneous/qpdfview.desktop.in > miscellaneous/qpdfview.desktop)
manual.files = miscellaneous/qpdfview.1
manual.path = $${MANUAL_INSTALL_PATH}
INSTALLS += target data launcher manual
|