~ahmed-a-ammar/pigment/pigment-gles2

AC_PREREQ(2.63)

# *** Package ***

AC_INIT([Pigment],[0.5.0.1],[https://code.fluendo.com/pigment/trac],[pigment])
AC_CONFIG_SRCDIR([src/pgm/pgm.h])
AC_CONFIG_MACRO_DIR([build/autotools])
AC_CONFIG_AUX_DIR([build/autotools])
AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([1.9 dist-bzip2])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

# CURRENT, REVISION, AGE
# - library source changed -> increment REVISION
# - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
# - interfaces added -> increment AGE
# - interfaces removed -> AGE = 0
PGM_LT_CURRENT=0
PGM_LT_REV=0
PGM_LT_AGE=0
PGM_LT_VERSION="$PGM_LT_CURRENT:$PGM_LT_REV:$PGM_LT_AGE"
PGM_LT_LDFLAGS="-version-info $PGM_LT_VERSION"
AC_SUBST(PGM_LT_VERSION)
AC_SUBST(PGM_LT_LDFLAGS)

PACKAGE_VERSION_MAJOR=`echo AC_PACKAGE_VERSION | cut -d'.' -f1`
PACKAGE_VERSION_MINOR=`echo AC_PACKAGE_VERSION | cut -d'.' -f2`
PACKAGE_VERSION_MICRO=`echo AC_PACKAGE_VERSION | cut -d'.' -f3`
AC_SUBST(PACKAGE_VERSION_MAJOR)
AC_SUBST(PACKAGE_VERSION_MINOR)
AC_SUBST(PACKAGE_VERSION_MICRO)

NANO=`echo AC_PACKAGE_VERSION | cut -d'.' -f4`
if test x"$NANO" = x || test "x$NANO" = "x0" ; then
    PIGMENT_TRUNK="no"
    PACKAGE_VERSION_NANO="0"
else
    PIGMENT_TRUNK="yes"
    PACKAGE_VERSION_NANO="$NANO"
fi
AC_SUBST(PIGMENT_TRUNK)
AC_SUBST(PACKAGE_VERSION_NANO)

PGM_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
AC_SUBST(PGM_MAJORMINOR)
AC_DEFINE_UNQUOTED(PGM_MAJORMINOR, "PGM_MAJORMINOR",
                   [library major.minor version])

# *** Checks for typedefs, structures, functions and programs ***

AC_USE_SYSTEM_EXTENSIONS
AC_PROG_CC
AM_PROG_CC_C_O
LT_INIT
AC_C_CONST
AC_C_INLINE

AC_CHECK_LIB(m, fabsf, AC_DEFINE(HAVE_FABSF, 1,
             [Define to 1 if you have the `fabsf' function.]))
AC_CHECK_LIB(m, sqrtf, AC_DEFINE(HAVE_SQRTF, 1,
             [Define to 1 if you have the `sqrtf' function.]))
AC_CHECK_LIB(m, sinf, AC_DEFINE(HAVE_SINF, 1,
             [Define to 1 if you have the `sinf' function.]))
AC_CHECK_LIB(m, cosf, AC_DEFINE(HAVE_COSF, 1,
             [Define to 1 if you have the `cosf' function.]))
AC_CHECK_LIB(m, sincosf, AC_DEFINE(HAVE_SINCOSF, 1,
             [Define to 1 if you have the `sincosf' function.]))
AC_CHECK_LIB(m, lrintf, AC_DEFINE(HAVE_LRINTF, 1,
             [Define to 1 if you have the `lrintf' function.]))
LT_LIB_M

AC_CHECK_FUNCS(uname)

AC_PATH_PROG([GLIB_MKENUMS], [glib-mkenums])
AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
PKG_PROG_PKG_CONFIG

# *** Versions of package requirements ***

AC_SUBST(glib_req, 2.8.0)
AC_SUBST(gstreamer_req, 0.10.0)
AC_SUBST(pango_req, 1.20)
AC_SUBST(pangocairo_req, 1.20)
AC_SUBST(cairo_req, 1.4)

# *** Pigment 3D graphics engine (deps checks) ***

PKG_CHECK_MODULES(GLIB, glib-2.0 >= $glib_req gobject-2.0 >= $glib_req gthread-2.0 >= $glib_req)
AC_SUBST(GLIB_CFLAGS)
AC_SUBST(GLIB_LIBS)

PKG_CHECK_MODULES(GDKPIXBUF, gdk-pixbuf-2.0)
AC_SUBST(GDKPIXBUF_CFLAGS)
AC_SUBST(GDKPIXBUF_LIBS)

# *** Pigment GUI classes (deps checks) ***

AC_ARG_ENABLE(gui-classes,
  AS_HELP_STRING([--disable-gui-classes],[disable build of GUI classes]),
    [
      case "${enableval}" in
        yes) ENABLE_GUI_CLASSES=yes ;;
        no)  ENABLE_GUI_CLASSES=no ;;
        *)   AC_MSG_ERROR(bad value ${enableval} for --disable-gui-classes) ;;
      esac
    ],
    [ENABLE_GUI_CLASSES=yes])
AM_CONDITIONAL(ENABLE_GUI_CLASSES, test "x$ENABLE_GUI_CLASSES" = "xyes")

PKG_CHECK_MODULES(PANGO, pango >= [$pango_req],
                  [HAVE_PANGO=yes], [HAVE_PANGO=no])
AM_CONDITIONAL(HAVE_PANGO, test x$HAVE_PANGO = xyes)
AC_SUBST(PANGO_CFLAGS)
AC_SUBST(PANGO_LIBS)

PKG_CHECK_MODULES(CAIRO, cairo >= [$cairo_req],
                  [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
AM_CONDITIONAL(HAVE_CAIRO, test x$HAVE_CAIRO = xyes)
AC_SUBST(CAIRO_CFLAGS)
AC_SUBST(CAIRO_LIBS)

PKG_CHECK_MODULES(PANGOCAIRO, pangocairo >= [$pangocairo_req],
                  [HAVE_PANGOCAIRO=yes], [HAVE_PANGOCAIRO=no])
AC_SUBST(PANGOCAIRO_CFLAGS)
AC_SUBST(PANGOCAIRO_LIBS)

if test x$HAVE_PANGO = xyes -a x$HAVE_CAIRO = xyes -a x$HAVE_PANGOCAIRO = xyes -a x$ENABLE_GUI_CLASSES = xyes; then
  HAVE_GUI_CLASSES="yes"
else
  HAVE_GUI_CLASSES="no"
fi
AC_SUBST(HAVE_GUI_CLASSES)
AM_CONDITIONAL(HAVE_GUI_CLASSES_COND, test x$HAVE_GUI_CLASSES = xyes)

# *** Pigment GStreamer classes (deps checks) ***

AC_ARG_ENABLE(gst-classes,
  AS_HELP_STRING([--disable-gst-classes],[disable build of GStreamer classes]),
    [
      case "${enableval}" in
        yes) ENABLE_GST_CLASSES=yes ;;
        no)  ENABLE_GST_CLASSES=no ;;
        *)   AC_MSG_ERROR(bad value ${enableval} for --disable-gst-classes) ;;
      esac
    ],
    [ENABLE_GST_CLASSES=yes])
AM_CONDITIONAL(ENABLE_GST_CLASSES, test "x$ENABLE_GST_CLASSES" = "xyes")

GST_MAJORMINOR=0.10
AC_SUBST(GST_MAJORMINOR)
PKG_CHECK_MODULES(GSTREAMERPLUGINSBASE,
                  gstreamer-plugins-base-0.10 >= [$gstreamer_req],
                  [HAVE_GSTREAMERPLUGINSBASE=yes],
                  [HAVE_GSTREAMERPLUGINSBASE=no])
AM_CONDITIONAL(HAVE_GSTREAMERPLUGINSBASE,
               test x$HAVE_GSTREAMERPLUGINSBASE = xyes)
AC_SUBST(GSTREAMERPLUGINSBASE_CFLAGS)
AC_SUBST(GSTREAMERPLUGINSBASE_LIBS)

if test x$HAVE_GUI_CLASSES = xyes -a x$HAVE_GSTREAMERPLUGINSBASE = xyes -a x$ENABLE_GST_CLASSES = xyes; then
  HAVE_GST_CLASSES="yes"
else
  HAVE_GST_CLASSES="no"
fi
AC_SUBST(HAVE_GST_CLASSES)
AM_CONDITIONAL(HAVE_GST_CLASSES_COND, test x$HAVE_GST_CLASSES = xyes)

# *** Pigment GTK+ classes (deps checks) ***

AC_ARG_ENABLE(gtk-classes,
  AS_HELP_STRING([--disable-gtk-classes],[disable build of GTK+ classes]),
    [
      case "${enableval}" in
        yes) ENABLE_GTK_CLASSES=yes ;;
        no)  ENABLE_GTK_CLASSES=no ;;
        *)   AC_MSG_ERROR(bad value ${enableval} for --disable-gtk-classes) ;;
      esac
    ],
    [ENABLE_GTK_CLASSES=yes])
AM_CONDITIONAL(ENABLE_GTK_CLASSES, test "x$ENABLE_GTK_CLASSES" = "xyes")

PKG_CHECK_MODULES(GTK, gtk+-2.0, [HAVE_GTK=yes], [HAVE_GTK=no])
AM_CONDITIONAL(HAVE_GTK, test x$HAVE_GTK = xyes)
AC_SUBST(GTK_CFLAGS)
AC_SUBST(GTK_LIBS)

if test x$HAVE_GTK = xyes -a x$ENABLE_GTK_CLASSES = xyes; then
  HAVE_GTK_CLASSES="yes"
else
  HAVE_GTK_CLASSES="no"
fi
AC_SUBST(HAVE_GTK_CLASSES)
AM_CONDITIONAL(HAVE_GTK_CLASSES_COND, test x$HAVE_GTK_CLASSES = xyes)

# *** OpenGL/GLX renderer (deps checks) ***

PKG_CHECK_MODULES(X11, x11, [HAVE_X11=yes], [HAVE_X11=no])
if test x$HAVE_X11 = xno; then
  AC_PATH_XTRA
  if test "x$no_x" = xyes; then
    AC_MSG_NOTICE(X11 development libraries not found);
  else
    XLIB_LIBS="$X_PRE_LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
    XLIB_CFLAGS="$X_CFLAGS"
    HAVE_X11="yes"
  fi
else
  XLIB_LIBS="$X11_LIBS"
  XLIB_CFLAGS="$X11_CFLAGS"
fi

AC_CHECK_HEADERS([GL/glx.h], [HAVE_GLX=yes], [HAVE_GLX=no])
AM_CONDITIONAL(HAVE_GLX_COND, test x$HAVE_GLX = xyes)

#PKG_CHECK_MODULES(GDKPIXBUFXLIB, gdk-pixbuf-xlib-2.0,
#                  [HAVE_GDKPIXBUFXLIB=yes], [HAVE_GDKPIXBUFXLIB=no])
#AC_SUBST(GDKPIXBUFXLIB_CFLAGS)
#AC_SUBST(GDKPIXBUFXLIB_LIBS)

PKG_CHECK_MODULES(XRENDER, xrender, [HAVE_XRENDER=yes], [HAVE_XRENDER=no])
AC_SUBST(XRENDER_CFLAGS)
AC_SUBST(XRENDER_LIBS)

AC_CHECK_HEADERS([GL/gl.h], [HAVE_GL=yes], [HAVE_GL=no])
if test x$HAVE_GL = xyes; then
  GL_LIBS="-lGL"
  GL_CFLAGS=""
fi
AM_CONDITIONAL(HAVE_GL_COND, test x$HAVE_GL = xyes)

if test x$HAVE_GL = xyes -a x$HAVE_X11 = xyes -a x$HAVE_GLX = xyes -a x$HAVE_XRENDER = xyes; then
  PGM_GL_LIBS="$GLIB_LIBS $XLIB_LIBS $XRENDER_LIBS $GL_LIBS"
  PGM_GL_CFLAGS="$GLIB_CFLAGS $XLIB_CFLAGS $XRENDER_CFLAGS $GL_CFLAGS"
  HAVE_OPENGL_PLUGIN="yes"
  OPENGL_BACKEND="(X11/GLX backend)"
  AC_SUBST(PGM_GL_CFLAGS)
  AC_SUBST(PGM_GL_LIBS)
else
  HAVE_OPENGL_PLUGIN="no"
  OPENGL_BACKEND=""
fi
AC_SUBST(HAVE_OPENGL_PLUGIN)
AC_SUBST(OPENGL_BACKEND)
AM_CONDITIONAL(HAVE_OPENGL_PLUGIN_COND, test x$HAVE_X11 = xyes -a x$HAVE_GLX = xyes -a x$HAVE_GL = xyes -a x$HAVE_XRENDER = xyes)

# *** OpenGL ES 1 renderer (deps checks) ***

AC_CHECK_HEADERS([GLES/egl.h], [HAVE_EGL=yes], [HAVE_EGL=no])
AC_CHECK_HEADERS([GLES/gl.h], [HAVE_GLES=yes], [HAVE_GLES=no])
AC_CHECK_HEADERS([GLES2/gl2.h], [HAVE_GLES2=yes], [HAVE_GLES2=no])
AC_CHECK_HEADERS([EGL/egl.h], [HAVE_EGL2=yes], [HAVE_EGL2=no])

AC_ARG_ENABLE(opengles1-gdl,
  AS_HELP_STRING([--enable-opengles1-gdl],[enable build of OpenGL ES 1 renderer using Intel GDL backend]),
    [
      case "${enableval}" in
        yes) ENABLE_OPENGLES1_GDL=yes ;;
        no)  ENABLE_OPENGLES1_GDL=no ;;
        *)   AC_MSG_ERROR(bad value ${enableval} for --enable-opengles1-gdl) ;;
      esac
    ],
    [ENABLE_OPENGLES1_GDL=no])

AC_ARG_ENABLE(opengles1-x11,
  AS_HELP_STRING([--enable-opengles1-x11],[enable build of OpenGL ES 1 renderer using X11 backend]),
    [
      case "${enableval}" in
        yes) ENABLE_OPENGLES1_X11=yes ;;
        no)  ENABLE_OPENGLES1_X11=no ;;
        *)   AC_MSG_ERROR(bad value ${enableval} for --enable-opengles1-x11) ;;
      esac
    ],
    [ENABLE_OPENGLES1_X11=no])

AC_ARG_ENABLE(opengles2-x11,
  AC_HELP_STRING([--enable-opengles2-x11], [enable build of OpenGL ES 2 renderer using X11 backend]),
    [
      case "${enableval}" in
        yes) ENABLE_OPENGLES2_X11=yes ;;
        no)  ENABLE_OPENGLES2_X11=no ;;
        *)   AC_MSG_ERROR(bad value ${enableval} for --enable-opengles2-x11) ;;
      esac
    ],
    [ENABLE_OPENGLES2_X11=no])

if test x$HAVE_EGL2 = xyes -a x$HAVE_GLES2 = xyes; then
   if test x$ENABLE_OPENGLES2_X11 = xyes -a x$HAVE_X11 = xyes; then
    AC_DEFINE([HAVE_EGL2_X11], [1],
              [Defined to 1 if the OpenGL ES 2 renderer uses the X11 backend])
    HAVE_OPENGLES2_PLUGIN="yes"
    OPENGLES2_BACKEND="(X11 backend)"
    PGM_GLES2_CFLAGS="$XLIB_CFLAG $GLIB_CFLAGS"
    PGM_GLES2_LIBS="$XLIB_LIBS $GLIB_LIBS -lGLESv2 -lEGL"
   else
    AC_DEFINE([HAVE_EGL2_NATIVE], [1],
              [Defined to 1 if the OpenGL ES 2 renderer uses the native backend])
    HAVE_OPENGLES2_PLUGIN="yes"
    OPENGLES2_BACKEND="(native backend)"
    PGM_GLES2_CFLAGS="$GLIB_CFLAGS"
    PGM_GLES2_LIBS="$GLIB_LIBS -lGLESv2 -lEGL"
   fi
else
  HAVE_OPENGLES2_PLUGIN="no"
  OPENGLES2_BACKEND=""
fi

if test x$HAVE_EGL = xyes -a x$HAVE_GLES = xyes; then
  if test x$ENABLE_OPENGLES1_GDL = xyes; then
    AC_CHECK_HEADERS([libgdl.h], [HAVE_GDL=yes], [HAVE_GDL=no])
    if test x$HAVE_GDL = xyes; then
      AC_DEFINE([HAVE_EGL_GDL], [1],
                [Defined to 1 if the OpenGL ES 1 renderer uses the GDL backend])
      HAVE_OPENGLES1_PLUGIN="yes"
      OPENGLES1_BACKEND="(Intel GDL backend)"
      PGM_GLES1_CFLAGS="$GLIB_CFLAGS"
      PGM_GLES1_LIBS="$GLIB_LIBS -lEGL -lgdl -lGLES_CM"
    else
      HAVE_OPENGLES1_PLUGIN="no"
      OPENGLES1_BACKEND=""
    fi
  elif test x$ENABLE_OPENGLES1_X11 = xyes; then
    if test x$HAVE_X11 = xyes; then
      AC_DEFINE([HAVE_EGL_X11], [1],
                [Defined to 1 if the OpenGL ES 1 renderer uses the X11 backend])
      HAVE_OPENGLES1_PLUGIN="yes"
      OPENGLES1_BACKEND="(X11 backend)"
      PGM_GLES1_CFLAGS="$XLIB_LIBS $GLIB_CFLAGS"
      PGM_GLES1_LIBS="$XLIB_LIBS $GLIB_LIBS -lGLES_CM -lEGL"
    else
      HAVE_OPENGLES1_PLUGIN="no"
      OPENGLES1_BACKEND=""
    fi
  else
    AC_DEFINE([HAVE_EGL_NATIVE], [1],
              [Defined to 1 if the OpenGL ES 1 renderer uses the native backend])
    HAVE_OPENGLES1_PLUGIN="yes"
    OPENGLES1_BACKEND="(native backend)"
    PGM_GLES1_CFLAGS="$GLIB_CFLAGS"
    PGM_GLES1_LIBS="$GLIB_LIBS -lGLES_CM -lEGL"
  fi
else
  HAVE_OPENGLES1_PLUGIN="no"
  OPENGLES1_BACKEND=""
fi

AC_SUBST(OPENGLES1_BACKEND)
AC_SUBST(HAVE_OPENGLES1_PLUGIN)
AC_SUBST(PGM_GLES1_CFLAGS)
AC_SUBST(PGM_GLES1_LIBS)

AC_SUBST(OPENGLES2_BACKEND)
AC_SUBST(HAVE_OPENGLES2_PLUGIN)
AC_SUBST(PGM_GLES2_CFLAGS)
AC_SUBST(PGM_GLES2_LIBS)

AM_CONDITIONAL(HAVE_OPENGLES1_PLUGIN_COND, test x$HAVE_OPENGLES1_PLUGIN = xyes)
AM_CONDITIONAL(HAVE_OPENGLES2_PLUGIN_COND, test x$HAVE_OPENGLES2_PLUGIN = xyes)
AM_CONDITIONAL(HAVE_OPENGLES_PLUGIN_COND, test x$HAVE_OPENGLES2_PLUGIN = xyes -o x$HAVE_OPENGLES1_PLUGIN = xyes )
AM_CONDITIONAL(HAVE_EGL_GDL_COND, test x$HAVE_EGL = xyes -a x$HAVE_GLES = xyes -a x$ENABLE_OPENGLES1_GDL = xyes)
AM_CONDITIONAL(HAVE_EGL_X11_COND, test x$HAVE_EGL = xyes -a x$HAVE_GLES = xyes -a x$ENABLE_OPENGLES1_X11 = xyes)
AM_CONDITIONAL(HAVE_EGL2_X11_COND, test x$HAVE_EGL2 = xyes -a x$HAVE_GLES2 = xyes -a x$ENABLE_OPENGLES2_X11 = xyes)
AM_CONDITIONAL(HAVE_EGL2_NATIVE_COND, test x$HAVE_EGL2 = xyes -a x$HAVE_GLES2 = xyes -a x$ENABLE_OPENGLES2_X11 = xno)
AM_CONDITIONAL(HAVE_EGL_NATIVE_COND, test x$HAVE_EGL = xyes -a x$HAVE_GLES = xyes -a x$ENABLE_OPENGLES1_X11 = xno -a x$ENABLE_OPENGLES1_GDL = xno)

# *** Documentation ***

GTK_DOC_CHECK([1.9])

# Don't build doc for SVN checkouts unless explicitly required
AM_CONDITIONAL([BUILD_GTK_DOC], [test "x$enable_gtk_doc" = "xyes" || test ! -f "autogen.sh"])

GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
AC_SUBST(GLIB_PREFIX)
AC_SUBST(CAIRO_PREFIX)

# *** Debug ***

if test x$PIGMENT_TRUNK = xyes; then
  DEFAULT_DEBUG="yes"
else
  DEFAULT_DEBUG="no"
fi
AC_SUBST(DEFAULT_DEBUG)
AC_ARG_ENABLE([debug],
              [AS_HELP_STRING([--enable-debug=@<:@no/yes/full@:>@],[Control debug level @<:@default=debug_default@:>@])],
              [], [enable_debug=$DEFAULT_DEBUG])
AS_CASE([$enable_debug],
        [full],
        [
          test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
          DEBUG_CFLAGS="-DPGM_RASTER_FRAME_INFOS"
        ],
        [yes],
        [
          test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
          DEBUG_CFLAGS="-DPGM_RASTER_FRAME_INFOS -DG_DISABLE_CAST_CHECKS"
        ],
        [no],
        [DEBUG_CFLAGS="-DPGM_DISABLE_LOGGER -DG_DISABLE_CAST_CHECKS -DG_DISABLE_CHECKS -DG_DISABLE_ASSERT"],
        [AC_MSG_ERROR([Unknown argument for --enable-debug])]
)
AC_SUBST(DEBUG_CFLAGS)

# *** Maintainer flags ***

if test x$PIGMENT_TRUNK = xyes; then
  DEFAULT_MAINTAINER_FLAGS="yes"
else
  DEFAULT_MAINTAINER_FLAGS="no"
fi
AC_SUBST(DEFAULT_MAINTAINER_FLAGS)
AC_ARG_ENABLE([maintainer-flags],
              [AS_HELP_STRING([--enable-maintainer-flags=@<:@no/yes@:>@],[Use strict compiler flags @<:@default=maintainer_flags_default@:>@])],
              [],
              [enable_maintainer_flags=$DEFAULT_MAINTAINER_FLAGS])
AS_IF([test "x$enable_maintainer_flags" = "xyes" && test "x$GCC" = "xyes"],
      [
        AS_COMPILER_FLAGS([MAINTAINER_CFLAGS],
                          ["-fno-common -Wall -Wextra -Werror -Wempty-body
                            -Wno-missing-field-initializers -Wstrict-aliasing=2
                            -Wno-unused-parameter -Wdeclaration-after-statement
                            -Wpointer-arith -Wcast-align -Wwrite-strings
                            -Wformat-security -Wformat-nonliteral -Winit-self
                            -Wmissing-declarations -Wnested-externs -Wundef
                            -Wold-style-definition -Wswitch-default
                            -Wstrict-prototypes -Wredundant-decls"])
      ]
)
AC_SUBST(MAINTAINER_CFLAGS)

# *** Variables ***

PGM_CFLAGS="\$(DEBUG_CFLAGS) \$(MAINTAINER_CFLAGS)"
AC_SUBST(PGM_CFLAGS)

PGM_PLUGIN_LDFLAGS="-export-symbols-regex '^[_]*pgm_plugin_info\$\$' -no-undefined -module -avoid-version"
AC_SUBST(PGM_PLUGIN_LDFLAGS)

AS_AC_EXPAND(PLUGIN_PATH, ${libdir}/pigment-$PGM_MAJORMINOR/$VERSION)
AC_SUBST(PLUGIN_PATH)
AC_DEFINE_UNQUOTED(PGM_PLUGIN_PATH, "$PLUGIN_PATH",
                   [The path where plugins are located])

# *** Configuration files ***

AC_CONFIG_FILES(
  Makefile
  src/Makefile
  src/pgm/Makefile
  src/pgm/pgm-version.h
  src/pgm/gtk/Makefile
  src/pgm/gui/Makefile
  src/pgm/gst/Makefile
  src/renderers/Makefile
  src/renderers/null/Makefile
  src/renderers/opengl/Makefile
  src/renderers/opengles/Makefile
  src/tools/Makefile
  src/examples/Makefile
  tests/Makefile
  tests/unit/Makefile
  tests/manual/Makefile
  tests/manual/pixbufs/Makefile
  doc/Makefile
  doc/design/Makefile
  doc/reference/Makefile
  doc/reference/version.xml
  pkgconfig/Makefile
  pkgconfig/pigment.pc
  pkgconfig/pigment-uninstalled.pc
  pkgconfig/pigment-gui.pc
  pkgconfig/pigment-gui-uninstalled.pc
  pkgconfig/pigment-gst.pc
  pkgconfig/pigment-gst-uninstalled.pc
  pkgconfig/pigment-gtk.pc
  pkgconfig/pigment-gtk-uninstalled.pc
  build/Makefile
  build/autotools/Makefile
  misc/Makefile
)
AC_OUTPUT

# *** Configuration summary ***

echo ""
echo "  Pigment $PACKAGE_VERSION"
echo "  ==============="
echo ""
echo "  Prefix:               ${prefix}"
echo "  Debugging:            ${enable_debug}"
echo "  3D graphics engine:   yes"
echo "  OpenGL renderer:      ${HAVE_OPENGL_PLUGIN} ${OPENGL_BACKEND}"
echo "  OpenGL ES 1 renderer: ${HAVE_OPENGLES1_PLUGIN} ${OPENGLES1_BACKEND}"
echo "  OpenGL ES 2 renderer: ${HAVE_OPENGLES2_PLUGIN} ${OPENGLES2_BACKEND}"
echo "  GUI classes:          ${HAVE_GUI_CLASSES}"
echo "  GStreamer classes:    ${HAVE_GST_CLASSES}"
echo "  GTK+ classes:         ${HAVE_GTK_CLASSES}"
echo "  Documentation:        ${enable_gtk_doc}"
echo ""
echo "  Compiler flags:      ${CPPFLAGS} ${DEBUG_CFLAGS} ${MAINTAINER_CFLAGS}"