1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
#-----------------------------------------------------------------------------
# Common variables for all projects.
#-----------------------------------------------------------------------------
#-----------------------------------------------------------------------------
# Common configuration for all projects.
#-----------------------------------------------------------------------------
CONFIG += link_pkgconfig
#MOC_DIR = .moc
#OBJECTS_DIR = .obj
RCC_DIR = resources
UI_DIR = ui
UI_HEADERS_DIR = ui/include
UI_SOURCES_DIR = ui/src
QMAKE_CXXFLAGS += -fno-exceptions \
-fno-rtti
# we don't like warnings...
QMAKE_CXXFLAGS += -Werror
TOP_SRC_DIR = $$PWD
#DEFINES += QT_NO_DEBUG_OUTPUT
DEFINES += SIGNON_TRACE
#-----------------------------------------------------------------------------
# setup the installation prefix
#-----------------------------------------------------------------------------
INSTALL_PREFIX = /usr # default installation prefix
# default prefix can be overriden by defining PREFIX when running qmake
isEmpty( PREFIX ) {
message("====")
message("==== NOTE: To override the installation path run: `qmake PREFIX=/custom/path'")
message("==== (current installation path is `$${INSTALL_PREFIX}')")
} else {
INSTALL_PREFIX = $${PREFIX}
message("====")
message("==== install prefix set to `$${INSTALL_PREFIX}'")
}
# Setup the library installation directory
exists( meego-release ) {
ARCH = $$system(tail -n1 meego-release)
} else {
ARCH = $$system(uname -m)
}
contains( ARCH, x86_64 ) {
INSTALL_LIBDIR = $${INSTALL_PREFIX}/lib64
} else {
INSTALL_LIBDIR = $${INSTALL_PREFIX}/lib
}
# default library directory can be overriden by defining LIBDIR when
# running qmake
isEmpty( LIBDIR ) {
message("====")
message("==== NOTE: To override the library installation path run: `qmake LIBDIR=/custom/path'")
message("==== (current installation path is `$${INSTALL_LIBDIR}')")
} else {
INSTALL_LIBDIR = $${LIBDIR}
message("====")
message("==== library install path set to `$${INSTALL_LIBDIR}'")
}
# Default directory for signond extensions
_PLUGINS = $$system(pkg-config --variable=plugindir signon-plugins)
isEmpty(_PLUGINS) {
error("plugin directory not available through pkg-config")
} else {
SIGNON_PLUGINS_DIR = $$_PLUGINS
}
SIGNON_PLUGINS_DIR_QUOTED = \\\"$$SIGNON_PLUGINS_DIR\\\"
include( coverage.pri )
|