~indicator-applet-developers/libindicate/trunk.12.10

AC_INIT(libindicate, 12.10.1, ted@canonical.com)

AC_PREREQ(2.53)

AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(libindicate, 12.10.1)

AM_MAINTAINER_MODE
m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES])

AC_ISC_POSIX
AC_PROG_CC
AM_PROG_CC_C_O
AC_STDC_HEADERS
AC_PROG_LIBTOOL

AC_SUBST(VERSION)
AC_CONFIG_MACRO_DIR([m4])

m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])

AC_PATH_PROG([GLIB_MKENUMS], [glib-mkenums])
AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])

###########################
# Libindicate versioning 
###########################

LIBINDICATE_CURRENT=5
LIBINDICATE_REVISION=7
LIBINDICATE_AGE=0

AC_SUBST(LIBINDICATE_CURRENT)
AC_SUBST(LIBINDICATE_REVISION)
AC_SUBST(LIBINDICATE_AGE)

###########################
# Libindicate GTK+ versioning 
###########################

LIBINDICATEGTK_CURRENT=3
LIBINDICATEGTK_REVISION=3
LIBINDICATEGTK_AGE=0

AC_SUBST(LIBINDICATEGTK_CURRENT)
AC_SUBST(LIBINDICATEGTK_REVISION)
AC_SUBST(LIBINDICATEGTK_AGE)

###########################
# Dependencies - GLib
###########################

DBUS_REQUIRED_VERSION=0.76
GLIB_REQUIRED_VERSION=2.18
GIO_REQUIRED_VERSION=2.18
DBUSMENU_REQUIRED_VERSION=0.3.97

PKG_CHECK_MODULES(LIBINDICATE, glib-2.0 >= $GLIB_REQUIRED_VERSION
                               gio-2.0 >= $GIO_REQUIRED_VERSION
                               dbusmenu-glib-0.4 >= $DBUSMENU_REQUIRED_VERSION
                               dbus-glib-1 >= $DBUS_REQUIRED_VERSION)
AC_SUBST(LIBINDICATE_CFLAGS)
AC_SUBST(LIBINDICATE_LIBS)

###########################
# Dependencies - GTK+
###########################

AC_ARG_WITH([gtk],
  [AS_HELP_STRING([--with-gtk],
    [Which version of gtk to use @<:@default=3@:>@])],
  [],
  [with_gtk=3])

GTK_REQUIRED_VERSION=2.12
GTK3_REQUIRED_VERSION=3.0
GDK_PIXBUF_REQUIRED_VERSION=2.12

AC_ARG_ENABLE([gtk],
	AC_HELP_STRING([--disable-gtk], [Disable libindicate-gtk library]),
	[enable_gtk=$enableval], [enable_gtk=auto])
AM_CONDITIONAL([WANT_LIBINDICATEGTK], [test "x$enable_gtk" != "xno"])

AS_IF([test "x$enable_gtk" != "xno"],[
AS_IF([test "x$with_gtk" = x2],
         [PKG_CHECK_MODULES(LIBINDICATEGTK, glib-2.0 >= $GLIB_REQUIRED_VERSION
                                            gio-2.0 >= $GIO_REQUIRED_VERSION
                                            gdk-pixbuf-2.0 >= $GDK_PIXBUF_REQUIRED_VERSION
                                            gtk+-2.0 >= $GTK_REQUIRED_VERSION
                                            dbusmenu-glib-0.4 >= $DBUSMENU_REQUIRED_VERSION
                                            dbus-glib-1 >= $DBUS_REQUIRED_VERSION,
                                            [have_gtk=yes])
         AC_DEFINE(HAVE_GTK3, 1, [whether gtk3 is available])
        ],
      [test "x$with_gtk" = x3],
         [PKG_CHECK_MODULES(LIBINDICATEGTK, glib-2.0 >= $GLIB_REQUIRED_VERSION
                                            gio-2.0 >= $GIO_REQUIRED_VERSION
                                            gdk-pixbuf-2.0
                                            gtk+-3.0 >= $GTK3_REQUIRED_VERSION
                                            dbusmenu-glib-0.4 >= $DBUSMENU_REQUIRED_VERSION
                                            dbus-glib-1 >= $DBUS_REQUIRED_VERSION,
                                            [have_gtk=yes])
        ],
      [AC_MSG_FAILURE([Value for --with-gtk was neither 2 nor 3])]
)

AC_SUBST(LIBINDICATEGTK_CFLAGS)
AC_SUBST(LIBINDICATEGTK_LIBS)
])

AM_CONDITIONAL(USE_GTK3, [test "x$with_gtk" = x3])

###########################
# gcov Coverage Reporting
###########################

m4_include([m4/gcov.m4])
AC_TDD_GCOV
AM_CONDITIONAL([HAVE_GCOV], [test "x$ac_cv_check_gcov" = xyes])
AM_CONDITIONAL([HAVE_LCOV], [test "x$ac_cv_check_lcov" = xyes])
AM_CONDITIONAL([HAVE_GCOVR], [test "x$ac_cv_check_gcovr" = xyes])
AC_SUBST(COVERAGE_CFLAGS)
AC_SUBST(COVERAGE_CXXFLAGS)
AC_SUBST(COVERAGE_LDFLAGS)

###########################
# GObject Introspection
###########################

GOBJECT_INTROSPECTION_CHECK([0.6.7])

###########################
# Vala API Generation
###########################

AC_PATH_PROG([VALA_API_GEN], [vapigen])

###########################
# Check for Mono support
###########################

MONO_REQUIRED_VERSION=1.0
PKG_CHECK_MODULES(MONO_DEPENDENCY, mono >= $MONO_REQUIRED_VERSION, has_mono=true, has_mono=false)

AC_PATH_PROG(AL, al, no)
if test "x$AL" = "xno" ; then
   AC_MSG_NOTICE([No al tool found.  You need to install Mono.])
fi

if test "x$has_mono" = "xtrue" ; then
   GENERATED_SOURCES=generated/*.cs
   AC_PATH_PROG(RUNTIME, mono, no)

   if test "x$RUNTIME" != "no" ; then
      RUNTIME=mono
   fi

   AC_PATH_PROG(CSC, gmcs, no)
   LIB_PREFIX=.so
   LIB_SUFFIX=
fi

if test "x$CSC" = "xno" ; then
   AC_MSG_NOTICE([No Mono compiler found.])
fi

AC_PATH_PROG(GACUTIL, gacutil, no)
if test "x$GACUTIL" = "xno" ; then
   AC_MSG_NOTICE([No gacutil tool found])
fi

AC_SUBST(RUNTIME)
AC_SUBST(CSC)
AC_SUBST(GACUTIL)
AC_SUBST(LIB_PREFIX)
AC_SUBST(LIB_SUFFIX)
AC_SUBST(GENERATED_SOURCES)

GLIB_SHARP_REQ_VERSION=2.12.1
GTK_SHARP_REQ_VERSION=2.12
PKG_CHECK_MODULES(GTK_SHARP, gtk-sharp-2.0 >= $GTK_SHARP_REQ_VERSION, has_gtksharp=true, has_gtksharp=false)
AC_SUBST(GTK_SHARP_LIBS)
AC_SUBST(GTK_SHARP_CFLAGS)

PKG_CHECK_MODULES(GAPI, gapi-2.0 >= $GLIB_SHARP_REQ_VERSION, has_gapi=true, has_gapi=false)
AC_PATH_PROG(GAPI_PARSER, gapi2-parser, no)
AC_SUBST(GAPI_PARSER)
AC_PATH_PROG(GAPI_CODEGEN, gapi2-codegen, no)
AC_SUBST(GAPI_CODEGEN)
AC_PATH_PROG(GAPI_FIXUP, gapi2-fixup, no)
AC_SUBST(GAPI_FIXUP)

###########################
# Check for Python support
###########################

AC_ARG_ENABLE([python],
	AC_HELP_STRING([--disable-python], [Disable Python bindings generation]),
	[enable_python=$enableval], [enable_python=auto])
AM_CONDITIONAL([WANT_PYTHON], [test "x$enable_python" != "xno"])

AS_IF([test "x$enable_python" != "xno"],[

PYTHON_REQUIRED=2.3.5
PYGTK_REQUIRED=2.14.0
PYGOBJECT_REQUIRED=0.22

AM_PATH_PYTHON([$PYTHON_REQUIRED])
AM_CHECK_PYTHON_HEADERS(,[AC_MSG_ERROR(could not find Python headers)])

PKG_CHECK_MODULES([INDICATE_PYTHON], [python-$PYTHON_VERSION >= $PYTHON_REQUIRED
                                      pygtk-2.0 >= $PYGTK_REQUIRED
                                      pygobject-2.0 >= $PYGOBJECT_REQUIRED],
                                     [have_python=yes]
)

# libpyglib-2.0-python* doesn't have a pkgconfig unfortunately
INDICATE_PYTHON_LIBS+=" -lpyglib-2.0-python$PYTHON_VERSION"

AC_SUBST(INDICATE_PYTHON_CFLAGS)
AC_SUBST(INDICATE_PYTHON_LIBS)

AC_MSG_CHECKING(for pygtk defs)
PYGTK_DEFSDIR=`$PKG_CONFIG --variable=defsdir pygtk-2.0`
AC_SUBST(PYGTK_DEFSDIR)
AC_MSG_RESULT($PYGTK_DEFSDIR)

AC_MSG_CHECKING(for pygtk codegen)
PYGTK_CODEGEN="$PYTHON `$PKG_CONFIG --variable=codegendir pygtk-2.0`/codegen.py"
AC_SUBST(PYGTK_CODEGEN)
AC_MSG_RESULT($PYGTK_CODEGEN)
])

###########################
# GTK Doc 
###########################

AC_ARG_ENABLE([doc],
	AC_HELP_STRING([--disable-doc], [Disable doc generation]),
	[enable_doc=$enableval], [enable_doc=auto])
AM_CONDITIONAL([WANT_DOC], [test "x$enable_doc" != "xno"])

GTK_DOC_CHECK([1.4])
AS_IF([test "x$enable_doc" != "xno"],[
GNOME_DOC_INIT
],[
# The initialisation is still needed for certain conditionals to be defined, just make it not output any error
GNOME_DOC_INIT(,,[:])
])
GNOME_COMPILE_WARNINGS

#########################
# Check if build tests
#########################
AC_ARG_ENABLE([tests],
	AC_HELP_STRING([--disable-tests], [Disable tests]),,
	[enable_tests=yes])
AM_CONDITIONAL([WANT_TESTS], [test "x$enable_tests" != "xno"])

##############################
# Custom Junk
##############################

AC_DEFUN([AC_DEFINE_PATH], [
  test "x$prefix" = xNONE && prefix="$ac_default_prefix"
  test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  ac_define_path=`eval echo [$]$2`
  ac_define_path=`eval echo [$]ac_define_path`
  $1="$ac_define_path"
  AC_SUBST($1)
  ifelse($3, ,
    AC_DEFINE_UNQUOTED($1, "$ac_define_path"),
    AC_DEFINE_UNQUOTED($1, "$ac_define_path", $3))
])

##############################
# ./configure Flags messings
##############################

cflags_set=${CFLAGS+set}
# find the actual value for $prefix that we'll end up with
REAL_PREFIX=
if test "x$prefix" = "xNONE"; then
  REAL_PREFIX=$ac_default_prefix
else
  REAL_PREFIX=$prefix
fi

# Have to go $sysconfdir->$prefix/etc->/usr/local/etc   
# if you actually know how to code shell then fix this :-)
SYSCONFDIR_TMP="$sysconfdir"
old_prefix=$prefix
prefix=$REAL_PREFIX
EXPANDED_SYSCONFDIR=`eval echo $SYSCONFDIR_TMP`
prefix=$old_prefix
AC_SUBST(EXPANDED_SYSCONFDIR)

dnl Save flags to aclocal
ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"

AC_DEFINE_PATH(PREFIX, "${prefix}", [prefix directory])
AC_DEFINE_PATH(SYSCONFDIR, "${sysconfdir}", [system configuration dir])
AC_DEFINE_PATH(LIBDIR, "${libdir}", [system configuration dir])

###########################
# Files
###########################

AM_CONDITIONAL([HAS_MONO], [test "x$has_mono" = "xtrue"])
AM_CONDITIONAL([HAS_PYTHON], [test "x$have_python" = "xyes"])

AC_CONFIG_FILES([
Makefile
libindicate/Makefile
libindicate/indicate-0.7.pc
libindicate-gtk/Makefile
libindicate-gtk/indicate-gtk-0.7.pc
libindicate-gtk/indicate-gtk3-0.7.pc
examples/Makefile
tests/Makefile
docs/Makefile
docs/reference/Makefile
docs/reference/version.xml
bindings/Makefile
bindings/python/Makefile
])

if test "x$has_mono" = "xtrue" ; then
   AC_CONFIG_FILES([
   examples/indicator-mono-example
   bindings/mono/Makefile
   bindings/mono/indicate/Makefile
   bindings/mono/indicate/indicate.sources.xml
   bindings/mono/indicate/indicate-sharp.dll.config
   bindings/mono/indicate/indicate-sharp-0.1.pc
   bindings/mono/indicate/AssemblyInfo.cs
   bindings/mono/indicate-gtk/Makefile
   bindings/mono/indicate-gtk/indicate-gtk.sources.xml
   bindings/mono/indicate-gtk/indicate-gtk-sharp.dll.config
   bindings/mono/indicate-gtk/indicate-gtk-sharp-0.1.pc
   bindings/mono/indicate-gtk/AssemblyInfo.cs
   ])
fi

AC_OUTPUT

###########################
# Results
###########################

AC_MSG_NOTICE([

Libindicate Configuration:

	Prefix:                 $prefix
	GObject Introspection:  $enable_introspection
	GTK+ Version:           $with_gtk
])

AM_COND_IF([HAVE_GNOME_DOC_UTILS],
	[AC_MSG_NOTICE([	Documentation:          yes])],
	[AC_MSG_NOTICE([	Documentation:          no])]
)

AS_IF([test "x$have_python" = "xyes"],
	[AC_MSG_NOTICE([	Python bindings:        yes])],
	[AC_MSG_NOTICE([	Python bindings:        no])]
)

AS_IF([test "x$have_gtk" = "xno"],
	[AC_MSG_NOTICE([	Gtk:                    no])],
	[AC_MSG_NOTICE([	Gtk:                    yes])]
)

AS_IF([test "x$enable_tests" != "xno"],
	[AC_MSG_NOTICE([	Tests:                  yes])],
	[AC_MSG_NOTICE([	Tests:                  no])]
)

AS_IF([test "x$use_gcov" = "xyes"],
	[AC_MSG_NOTICE([	gcov:                   yes])],
	[AC_MSG_NOTICE([	gcov:                   no])]
)