1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
|
AC_INIT([Credentials Control Center],
[0.0.7],
[https://bugs.launchpad.net/opensesame-gnome-control-center],
[credentials-control-center],
[https://launchpad.net/opensesame-gnome-control-center])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_SRCDIR([src/cc-credentials-panel.c])
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_MACRO_DIR([m4])
AM_INIT_AUTOMAKE([1.11 -Wall no-dist-gzip dist-bzip2 tar-ustar no-define subdir-objects])
AM_MAINTAINER_MODE([enable])
AM_SILENT_RULES([yes])
# Gobject Introspection
GOBJECT_INTROSPECTION_CHECK([1.30.0])
# Check for programs
AC_PROG_CC
AM_PROG_CC_C_O
OVERRIDE_PROG_VALAC([0.15.1], [valac-0.16 valac-0.14 valac])
LT_PREREQ([2.2])
LT_INIT([disable-static])
# API reference documentation.
# The gtk-doc check MUST appear after the libtool check, so that
# gtkdoc-scangobj can parse libtool archives.
GTK_DOC_CHECK([1.14], [--flavour no-tmpl])
# Internationalization support
IT_PROG_INTLTOOL([0.40.1])
AC_SUBST([GETTEXT_PACKAGE], [$PACKAGE_TARNAME])
AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE", [Gettext package])
GNOME_COMPILE_WARNINGS([maximum])
GNOME_MAINTAINER_MODE_DEFINES
PKG_PROG_PKG_CONFIG([0.24])
# Libraries
LIBACCOUNTS_GLIB_REQUIRED="libaccounts-glib"
LIBSIGNON_GLIB_REQUIRED="libsignon-glib"
GLIB_REQUIRED="glib-2.0 gio-2.0 gio-unix-2.0 >= 2.29.5"
GTK_REQUIRED="gtk+-3.0 >= 3.0.0"
GNOME_CONTROL_CENTER_REQUIRED="libgnome-control-center"
# Unfortunately we need this in order to store the cookies (D-Bus signature
# a{ss}) into a GValue
DBUS_GLIB_REQUIRED="dbus-glib-1"
PKG_CHECK_MODULES([CREDENTIALS_PANEL],
[$LIBACCOUNTS_GLIB_REQUIRED
$LIBSIGNON_GLIB_REQUIRED
$GLIB_REQUIRED
$GTK_REQUIRED
$GNOME_CONTROL_CENTER_REQUIRED])
# libaccount-plugin variables.
AC_SUBST([LIBACCOUNT_PLUGIN_SO_VERSION], [0:0:0])
AC_SUBST([LIBACCOUNT_PLUGIN_API_VERSION], [1.0])
LIBACCOUNT_PLUGIN_DIR="$libdir/libaccount-plugin-$LIBACCOUNT_PLUGIN_API_VERSION"
AC_SUBST(LIBACCOUNT_PLUGIN_DIR)
# libaccount-plugin dependencies.
PKG_CHECK_MODULES([LIBACCOUNT_PLUGIN],
[$DBUS_GLIB_REQUIRED
$LIBACCOUNTS_GLIB_REQUIRED
$LIBSIGNON_GLIB_REQUIRED
$GLIB_REQUIRED
$GTK_REQUIRED])
# Check for GLib testing utilities.
AC_PATH_PROG([GTESTER], [gtester], [notfound])
AC_PATH_PROG([GTESTER_REPORT], [gtester-report], [notfound])
AS_IF([test "x$GTESTER" = "xnotfound" -o "x$GTESTER_REPORT" = "xnotfound"],
[AC_MSG_WARN([testing disabled as the required utilities were not found])],
[CREDENTIALS_ENABLE_TESTS=true
AC_SUBST([GTESTER])
AC_SUBST([GTESTER_REPORT])])
AM_CONDITIONAL([CREDENTIALS_ENABLE_TESTS], [test "x$CREDENTIALS_ENABLE_TESTS" = "xtrue"])
# Check for lcov.
AC_ARG_ENABLE([lcov],
[AS_HELP_STRING([--disable-lcov], [Disable lcov code coverage testing])])
AS_IF([test "x$enable_lcov" != "xno"],
[AC_PATH_PROG([LCOV], [lcov], [notfound])
AC_PATH_PROG([LCOV_GENHTML], [genhtml], [notfound])
AS_IF([test "x$LCOV" = "xnotfound" -o "x$LCOV_GENHTML" = "xnotfound"],
[have_lcov=no],
[have_lcov=yes])],
[have_lcov=no])
AS_IF([test "x$have_lcov" = "xyes"],
[AC_SUBST([LCOV])
AC_SUBST([LCOV_GENHTML])
CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
LDFLAGS="$LDFLAGS -lgcov"],
[AS_IF([test "x$enable_lcov" = "xyes"],
[AC_MSG_ERROR([lcov code coverage reporting requested but not found])])])
AM_CONDITIONAL([CREDENTIALS_ENABLE_LCOV], [test "x$have_lcov" = "xyes"])
# Mallard help.
YELP_HELP_INIT
AC_CONFIG_FILES([
Makefile
data/gnome-credentials-panel.desktop.in
doc/account-plugin/Makefile
doc/account-plugin/version.xml
help/Makefile
libaccount-plugin/account-plugin.pc
po/Makefile.in
])
AC_OUTPUT
|