1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
include(qpdfview.pri)
TARGET = qpdfview
TEMPLATE = app
HEADERS += \
sources/annotationdialog.h \
sources/formfielddialog.h \
sources/pageitem.h \
sources/searchthread.h \
sources/presentationview.h \
sources/documentview.h \
sources/miscellaneous.h \
sources/settingsdialog.h \
sources/printoptionswidget.h \
sources/recentlyusedmenu.h \
sources/bookmarkmenu.h \
sources/mainwindow.h
SOURCES += \
sources/annotationdialog.cpp \
sources/formfielddialog.cpp \
sources/pageitem.cpp \
sources/searchthread.cpp \
sources/presentationview.cpp \
sources/documentview.cpp \
sources/miscellaneous.cpp \
sources/settingsdialog.cpp \
sources/printoptionswidget.cpp \
sources/recentlyusedmenu.cpp \
sources/bookmarkmenu.cpp \
sources/mainwindow.cpp \
sources/main.cpp
TRANSLATIONS += \
translations/qpdfview_ast.ts \
translations/qpdfview_ca.ts \
translations/qpdfview_cs.ts \
translations/qpdfview_da.ts \
translations/qpdfview_de.ts \
translations/qpdfview_el.ts \
translations/qpdfview_en_GB.ts \
translations/qpdfview_es.ts \
translations/qpdfview_fi.ts \
translations/qpdfview_fr.ts \
translations/qpdfview_he.ts \
translations/qpdfview_hr.ts \
translations/qpdfview_it.ts \
translations/qpdfview_my.ts \
translations/qpdfview_pt_BR.ts \
translations/qpdfview_ro.ts \
translations/qpdfview_ru.ts \
translations/qpdfview_sk.ts \
translations/qpdfview_tr.ts \
translations/qpdfview_ug.ts \
translations/qpdfview_uk.ts \
translations/qpdfview_zh_CN.ts
QT += core xml gui
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
!without_svg {
DEFINES += WITH_SVG
QT += svg
RESOURCES += qpdfview.qrc
}
!without_dbus {
DEFINES += WITH_DBUS
QT += dbus
}
!without_pkgconfig {
CONFIG += link_pkgconfig
PKGCONFIG += poppler-qt4
system(pkg-config --atleast-version=0.14 poppler-qt4):DEFINES += HAS_POPPLER_14
system(pkg-config --atleast-version=0.20.1 poppler-qt4):DEFINES += HAS_POPPLER_20
system(pkg-config --atleast-version=0.22 poppler-qt4):DEFINES += HAS_POPPLER_22
}
!without_cups {
DEFINES += WITH_CUPS
LIBS += $$system(cups-config --libs)
}
!without_synctex {
DEFINES += WITH_SYNCTEX
LIBS += -lz
INCLUDEPATH += synctex
SOURCES += synctex/synctex_parser.c synctex/synctex_parser_utils.c
}
target.path = $${TARGET_INSTALL_PATH}
data.files = icons/qpdfview.svg translations/*.qm miscellaneous/help.html
data.path = $${DATA_INSTALL_PATH}
DEFINES += DATA_INSTALL_PATH=\\\"$${DATA_INSTALL_PATH}\\\"
launcher.files = miscellaneous/qpdfview.desktop
launcher.path = $${LAUNCHER_INSTALL_PATH}
system(sed \"s/DATA_INSTALL_PATH/$$replace(DATA_INSTALL_PATH, "/", "\\/")/\" miscellaneous/qpdfview.desktop.in > miscellaneous/qpdfview.desktop)
manual.files = miscellaneous/qpdfview.1
manual.path = $${MANUAL_INSTALL_PATH}
INSTALLS += target data launcher manual
|