~mvo/click/lp1319790-chroot-fstab

# Checks for existence of coverage tools:

#  * gcov

#  * lcov

#  * genhtml

#  * gcovr

# 

# Sets ac_cv_check_gcov to yes if tooling is present

# and reports the executables to the variables LCOV, GCOVR and GENHTML.

AC_DEFUN([AC_TDD_GCOV],

[

  AC_ARG_ENABLE(gcov,

  AS_HELP_STRING([--enable-gcov],

                 [enable coverage testing with gcov]),

  [use_gcov=$enableval], [use_gcov=no])

 

  if test "x$use_gcov" = "xyes"; then

  # we need gcc:

  if test "$GCC" != "yes"; then

    AC_MSG_ERROR([GCC is required for --enable-gcov])

  fi

 

  # Check if ccache is being used

  AC_CHECK_PROG(SHTOOL, shtool, shtool)

  case `test "$SHTOOL" && $SHTOOL path $CC` in

    *ccache*[)] gcc_ccache=yes;;

    *[)] gcc_ccache=no;;

  esac

 

  if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then

    AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])

  fi

 

  AC_CHECK_PROG(LCOV, lcov, lcov)

  AC_CHECK_PROG(GENHTML, genhtml, genhtml)

 

  if test -z "$LCOV"; then

    AC_MSG_ERROR([To enable code coverage reporting you must have lcov installed])

  fi

 

  if test -z "$GENHTML"; then

    AC_MSG_ERROR([Could not find genhtml from the lcov package])

  fi

 

  ac_cv_check_gcov=yes

  ac_cv_check_lcov=yes

 

  # Remove all optimization flags from CFLAGS

  changequote({,})

  CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`

  changequote([,])

 

  # Add the special gcc flags

  COVERAGE_CFLAGS="-O0 -fprofile-arcs -ftest-coverage"

  COVERAGE_CXXFLAGS="-O0 -fprofile-arcs -ftest-coverage"        

  COVERAGE_LDFLAGS="-lgcov"

 

  # Check availability of gcovr

  AC_CHECK_PROG(GCOVR, gcovr, gcovr)

  if test -z "$GCOVR"; then

    AC_MSG_ERROR([To enable code coverage reporting you must have gcovr installed])

  fi

  ac_cv_check_gcovr=yes

 

fi

]) # AC_TDD_GCOV