# Check http://webdev.elementaryos.org/docs/developer-guide/cmake for documentation

cmake_minimum_required (VERSION 2.6)
cmake_policy (VERSION 2.6)
project (appstore)

set (PKG_NAME ${CMAKE_PROJECT_NAME})
set (PKG_VERSION 0.2)
set (API_VERSION 1.0)

# Used to create GObject introspection files
set (PKG_GIR_NAME AppStore)

list (APPEND CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/)

set (RESOURCES_DIR ${CMAKE_INSTALL_PREFIX}/share/${PKG_NAME}/)
set (GETTEXT_PACKAGE ${PKG_NAME})

set (CPACK_PACKAGE_VERSION ${PKG_VERSION})
set (CPACK_SOURCE_GENERATOR "TGZ")
set (CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${CPACK_PACKAGE_VERSION}")
set (CPACK_SOURCE_IGNORE_FILES "/build/;/.bzr/;/.bzrignore;~$;${CPACK_SOURCE_IGNORE_FILES}")

include (CPack)
add_custom_target (dist COMMAND ${CMAKE_MAKE_PROGRAM} package_source)

find_package (Vala REQUIRED)
include (ValaVersion)
include (ValaPrecompile)

ensure_vala_version ("0.16.1" MINIMUM)

#
# Packages in PKG_DEPS are used with the vala compiler and other related tools (not versioned.)
# Packages in PKG_DEPS_CHECK are used with PKG-Config and for linking, etc. They can contain versions.
#
# Both should contain *the same packages*, except for those whose VAPI file has a different name. In
# such case, PKG_DEPS would use the name of the VAPI, and PKG_DEPS_CHECK would use the name of the
# package known by pkg-config.
#

find_package (PkgConfig)

set (PKG_DEPS
    sqlheavy-0.1
    gee-0.8)

set (PKG_DEPS_CHECK
    packagekit-glib2
    sqlheavy-0.1
    gthread-2.0
    gee-0.8)
set (VALAC_OPTIONS
     --thread
     --target-glib=2.32)

# Optional Gtk+ support
option (DISABLE_GTK "Disable Gtk+ support auto-detection" OFF)
option (WANT_GTK "Enable Gtk+ support" OFF)

set (GTK_DEPS gtk+-3.0)
set (GTK_DEPS_CHECK gtk+-3.0>=3.3.14)

if(WANT_GTK)
  message(STATUS "Enabled Gtk+ support.")
  pkg_check_modules (GTK REQUIRED ${GTK_DEPS_CHECK})
else()
  if(DISABLE_GTK)
    message(STATUS "Disabled Gtk+ auto-detection (Gtk+ support will be disabled).")
  else ()
    message(STATUS "Using Gtk+ auto-detection (Gtk+ support might be enabled).")
    pkg_check_modules (GTK ${GTK_DEPS_CHECK})
    if (${GTK_FOUND})
      message("-- Gtk+ support, ON")
    else ()
      message("-- Gtk+ support, OFF")
    endif ()
  endif()
endif()

if (${GTK_FOUND})
    set (PKG_DEPS ${GTK_DEPS} ${PKG_DEPS})
    set (PKG_DEPS_CHECK ${GTK_DEPS_CHECK} ${PKG_DEPS_CHECK})
    set (VALAC_OPTIONS ${VALAC_OPTIONS} -D HAVE_GTK)
endif ()

# GI dependencies
set (GI_PKG_DEPS Gtk-3.0 Gee-0.8)

# Check for the deps
pkg_check_modules (DEPS REQUIRED ${PKG_DEPS_CHECK})


if (CMAKE_SYSTEM_NAME MATCHES "Linux")
    set (VALAC_OPTIONS ${VALAC_OPTIONS} --define=LINUX)
endif ()

add_subdirectory (lib)
#add_subdirectory (tools)
#add_subdirectory (doc)
#add_subdirectory (po)