1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
######################################################################
# Communi
######################################################################
TEMPLATE = subdirs
SUBDIRS += src ircclient
CONFIG += ordered
lessThan(QT_MAJOR_VERSION, 5) {
lessThan(QT_MAJOR_VERSION, 4) | lessThan(QT_MINOR_VERSION, 6) {
error(Communi requires Qt 4.6 or newer but Qt $$[QT_VERSION] was detected.)
}
}
CONFIG_VARS = $${OUT_PWD}$${QMAKE_DIR_SEP}.config.vars
QMAKE_CACHE = $${OUT_PWD}$${QMAKE_DIR_SEP}.qmake.cache
IRC_CONFIG = $${OUT_PWD}$${QMAKE_DIR_SEP}communi-config.prf
static {
system(echo DEFINES+=IRC_STATIC > $$QMAKE_CACHE)
system(echo DEFINES+=IRC_STATIC > $$IRC_CONFIG)
} else {
system(echo DEFINES+=IRC_SHARED > $$QMAKE_CACHE)
system(echo DEFINES+=IRC_SHARED > $$IRC_CONFIG)
}
exists($$CONFIG_VARS) {
system(echo include\\\($$CONFIG_VARS\\\) >> $$QMAKE_CACHE)
}
isEmpty(IRC_INSTALL_LIBS):IRC_INSTALL_LIBS = $$[QT_INSTALL_LIBS]
isEmpty(IRC_INSTALL_BINS):IRC_INSTALL_BINS = $$[QT_INSTALL_BINS]
isEmpty(IRC_INSTALL_HEADERS):IRC_INSTALL_HEADERS = $$[QT_INSTALL_HEADERS]/Communi
isEmpty(IRC_INSTALL_FEATURES):IRC_INSTALL_FEATURES = $$[QT_INSTALL_DATA]/mkspecs/features
# qt4/win: WARNING: Unescaped backslashes are deprecated
!win32|greaterThan(QT_MAJOR_VERSION, 4) {
system(echo IRC_INSTALL_LIBS=$$IRC_INSTALL_LIBS >> $$QMAKE_CACHE)
system(echo IRC_INSTALL_LIBS=$$IRC_INSTALL_LIBS >> $$IRC_CONFIG)
system(echo IRC_INSTALL_BINS=$$IRC_INSTALL_BINS >> $$QMAKE_CACHE)
system(echo IRC_INSTALL_BINS=$$IRC_INSTALL_BINS >> $$IRC_CONFIG)
system(echo IRC_INSTALL_HEADERS=$$IRC_INSTALL_HEADERS >> $$QMAKE_CACHE)
system(echo IRC_INSTALL_HEADERS=$$IRC_INSTALL_HEADERS >> $$IRC_CONFIG)
system(echo IRC_INSTALL_FEATURES=$$IRC_INSTALL_FEATURES >> $$QMAKE_CACHE)
system(echo IRC_INSTALL_FEATURES=$$IRC_INSTALL_FEATURES >> $$IRC_CONFIG)
}
OTHER_FILES += .travis.yml
OTHER_FILES += AUTHORS
OTHER_FILES += CHANGELOG
OTHER_FILES += INSTALL
OTHER_FILES += LICENSE
OTHER_FILES += README
OTHER_FILES += features/communi.prf
features.files += features/communi.prf
features.files += $$OUT_PWD/communi-config.prf
features.path = $$IRC_INSTALL_FEATURES
INSTALLS += features
include(version.pri)
!build_pass {
macx {
!qt_no_framework {
message(Building Communi $$IRC_VERSION (framework))
} else {
message(Building Communi $$IRC_VERSION (dylib))
}
} else {
message(Building Communi $$IRC_VERSION)
}
}
coverage {
cov_zerocounters.CONFIG += recursive
cov_zerocounters.recurse = src
QMAKE_EXTRA_TARGETS += cov_zerocounters
cov_capture.CONFIG += recursive
cov_capture.recurse = src
QMAKE_EXTRA_TARGETS += cov_capture
cov_genhtml.CONFIG += recursive
cov_genhtml.recurse = src
QMAKE_EXTRA_TARGETS += cov_genhtml
coverage.depends += first cov_zerocounters check cov_capture cov_genhtml
QMAKE_EXTRA_TARGETS += coverage
!build_pass:message(Code coverage collection enabled)
}
|