~ubuntu-branches/ubuntu/intrepid/xfce-mcs-plugins/intrepid-proposed

dnl $Id: configure.in.in 28446 2008-10-26 21:09:21Z olivier $
dnl
dnl Copyright (c) 2002-2007
dnl         The Xfce development team. All rights reserved.
dnl
dnl Written for Xfce by Olivier Fourdan <fourdan@xfce.org>, Jasper
dnl Huijsmans <jasper@xfce.org> and Benedikt Meurer <benny@xfce.org>.
dnl Portions based on gnome capplets by Jonathan Blandford <jrb@gnome.org>.
dnl

dnl ***************************
dnl *** Version information ***
dnl ***************************
m4_define([xfce_mcs_plugins_version_major], [4])
m4_define([xfce_mcs_plugins_version_minor], [4])
m4_define([xfce_mcs_plugins_version_micro], [3])
m4_define([xfce_mcs_plugins_version_nano], [])
m4_define([xfce_mcs_plugins_version_build], [28474])
m4_define([xfce_mcs_plugins_version_tag], [])
m4_define([xfce_mcs_plugins_version], [xfce_mcs_plugins_version_major().xfce_mcs_plugins_version_minor().xfce_mcs_plugins_version_micro()ifelse(xfce_mcs_plugins_version_nano(), [], [], [.xfce_mcs_plugins_version_nano()])ifelse(xfce_mcs_plugins_version_tag(), [svn], [xfce_mcs_plugins_version_tag()-xfce_mcs_plugins_version_build()], [xfce_mcs_plugins_version_tag()])])


dnl # DO NOT MODIFY ANYTHING BELOW THIS LINE, UNLESS YOU KNOW WHAT
dnl # YOU ARE DOING.


dnl *******************************************
dnl *** Debugging support for SVN snapshots ***
dnl *******************************************
m4_define([xfce_mcs_plugins_debug_default], [ifelse(xfce_mcs_plugins_version_tag(), [svn], [yes], [minimum])])

dnl ***************************
dnl *** Initialize autoconf ***
dnl ***************************
AC_COPYRIGHT([Copyright (c) 2002-2007
        The Xfce development team. All rights reserved.

Written for Xfce by Olivier Fourdan <fourdan@xfce.org>, Jasper
Huijsmans <jasper@xfce.org> and Benedikt Meurer <benny@xfce.org>.
Portions based on gnome capplets by Jonathan Blandford <jrb@gnome.org>.])
AC_INIT([xfce-mcs-plugins], [xfce_mcs_plugins_version], [xfce4-dev@xfce.org])
AC_PREREQ([2.50])
AC_REVISION([$Id: configure.in.in 28446 2008-10-26 21:09:21Z olivier $])
AC_PROG_MAKE_SET()

dnl ***************************
dnl *** Initialize automake ***
dnl ***************************
AM_INIT_AUTOMAKE([AC_PACKAGE_TARNAME()], [AC_PACKAGE_VERSION()])
AM_CONFIG_HEADER([config.h])
AM_MAINTAINER_MODE()

dnl *******************************
dnl *** Check for UNIX variants ***
dnl *******************************
AC_AIX()
AC_ISC_POSIX()
AC_MINIX()
AM_CONDITIONAL([HAVE_CYGWIN], [test "`uname | grep \"CYGWIN\"`" != ""])

dnl ********************************
dnl *** Check for basic programs ***
dnl ********************************
AC_PROG_CC()
AC_PROG_INSTALL()
AC_PROG_INTLTOOL([0.31], [no-xml])
AC_PROG_LIBTOOL()

dnl ***************************************
dnl *** Check for standard header files ***
dnl ***************************************
AC_HEADER_STDC()
AC_CHECK_HEADERS([dirent.h])
AC_CHECK_FUNCS([opendir])

dnl ******************************
dnl *** Check for i18n support ***
dnl ******************************
XDT_I18N([am ar az be bg bn_IN ca cs da de dz el en_GB eo es es_MX et eu fa fi fr gl gu he hi hu id it ja ka ko ku lt lv mk mr ms nb_NO nl pa pl pt_BR pt_PT ro ru si sk sv ta tr uk ur vi zh_CN zh_TW])

dnl *********************
dnl *** Check for X11 ***
dnl *********************
XDT_CHECK_LIBX11_REQUIRE()

dnl ********************************************
dnl *** Check for xf86misc (keyboard plugin) ***
dnl ********************************************
AC_ARG_ENABLE([xf86misc],
AC_HELP_STRING([--enable-xf86misc], [try to use the xf86misc extension])
AC_HELP_STRING([--disable-xf86misc], [don't try to use the xf86misc extension]),
  [], [enable_xf86misc=no])
XF86MISC_CFLAGS= XF86MISC_LIBS=
if test x"$enable_xf86misc" = x"yes"; then
  ac_save_CFLAGS="$CFLAGS"
  ac_save_LIBS="$LIBS"
  CFLAGS="$CFLAGS $CPPFLAGS $LIBX11_CFLAGS"
  LIBS="$LIBS $LIBX11_LDFLAGS $LIBX11_LIBS -lXext -lXxf86misc"
  AC_MSG_CHECKING([whether we can use the xf86misc extension])
  AC_TRY_LINK(
  [
#include <X11/Xlib.h>
#include <X11/extensions/xf86misc.h>
  ], [Bool b = XF86MiscQueryVersion((void *)0, (void *)0, (void *)0);],
  [
    XF86MISC_CFLAGS="-DUSE_XF86MISC"
    XF86MISC_LIBS="-lXext -lXxf86misc"
    AC_MSG_RESULT([yes])
  ], [ AC_MSG_RESULT([no]) ])
  CFLAGS="$ac_save_CFLAGS"
  LIBS="$ac_save_LIBS"
fi
AC_SUBST([XF86MISC_CFLAGS])
AC_SUBST([XF86MISC_LIBS])

dnl ***********************************
dnl Check for XKB (keyboard plugin) ***
dnl ***********************************
AC_ARG_ENABLE([xkb],
AC_HELP_STRING([--enable-xkb], [try to use the XKB extension])
AC_HELP_STRING([--disable-xkb], [don't try to use the XKB extension]),
  [], [enable_xkb=yes])
XKB_CFLAGS= XKB_LIBS=
if test x"$enable_xkb" = x"yes"; then
  ac_save_CFLAGS="$CFLAGS"
  ac_save_LIBS="$LIBS"
  CFLAGS="$CFLAGS $CPPFLAGS $LIBX11_CFLAGS"
  LIBS="$LIBS $LIBX11_LDFLAGS $LIBX11_LIBS -lXext"
  AC_MSG_CHECKING([whether we can use the XKB extension])
  AC_TRY_LINK(
  [
#include <X11/Xlib.h>
#include <X11/XKBlib.h>
  ], [ Bool b = XkbLibraryVersion((void *)0, (void *)0); ],
  [
    XKB_CFLAGS="-DUSE_XKB"
    XKB_LIBS="-lXext"
    AC_MSG_RESULT([yes])
  ], [ AC_MSG_RESULT([no]) ])
  CFLAGS="$ac_save_CFLAGS"
  LIBS="$ac_save_LIBS"
fi
AC_SUBST([XKB_CFLAGS])
AC_SUBST([XKB_LIBS])

dnl **********************************
dnl *** Check for XINPUT extension ***
dnl **********************************
AC_ARG_ENABLE([xinput],
AC_HELP_STRING([--enable-xinput], [try to use the XINPUT extension])
AC_HELP_STRING([--disable-xinput], [don't try to use the XINPUT extension]),
  [], [enable_xinput=yes])
XINPUT_CFLAGS= XINPUT_LIBS=
if test x"$enable_xinput" = x"yes"; then
  ac_save_CFLAGS="$CFLAGS"
  ac_save_LIBS="$LIBS"
  CFLAGS="$CFLAGS $CPPFLAGS $LIBX11_CFLAGS"
  LIBS="$LIBS $LIBX11_LDFLAGS $LIBX11_LIBS -lXi"
  AC_MSG_CHECKING([whether we can use the XINPUT extension])
  AC_TRY_LINK(
  [
#include <X11/Xlib.h>
#include <X11/extensions/XInput.h>
  ], [ XDeviceInfo *device_info = XListInputDevices ((void *)0, (void *)0); ],
  [
    XINPUT_CFLAGS="-DUSE_XINPUT"
    XINPUT_LIBS="-lXi"
    AC_MSG_RESULT([yes])
  ], [ AC_MSG_RESULT([no]) ])
  CFLAGS="$ac_save_CFLAGS"
  LIBS="$ac_save_LIBS"
fi
AC_SUBST([XINPUT_CFLAGS])
AC_SUBST([XINPUT_LIBS])

dnl *********************************
dnl *** Check for RANDR extension ***
dnl *********************************
AC_ARG_ENABLE([randr],
AC_HELP_STRING([--enable-randr], [try to use the XRANDR extension])
AC_HELP_STRING([--disable-randr], [don't try to use the XRANDR extension]),
  [], [enable_randr=yes])
XRANDR_CFLAGS= XRANDR_LIBS=
if test x"$enable_randr" = x"yes"; then
  ac_save_CFLAGS="$CFLAGS"
  ac_save_LIBS="$LIBS"
  CFLAGS="$CFLAGS $CPPFLAGS $LIBX11_CFLAGS"
  LIBS="$LIBS $LIBX11_LDFLAGS $LIBX11_LIBS -lXext -lXrandr -lXrender"
  AC_MSG_CHECKING([whether we can use the XRANDR extension])
  AC_TRY_LINK(
  [
#include <X11/Xlib.h>
#include <X11/extensions/Xrandr.h>
  ], [XRRScreenConfiguration *sc = XRRGetScreenInfo((void *)0, (void *)0); ],
  [
    XRANDR_CFLAGS="-DUSE_XRANDR"
    XRANDR_LIBS="-lXext -lXrandr -lXrender"
    AC_MSG_RESULT([yes])
  ], [ AC_MSG_RESULT([no]) ])
  CFLAGS="$ac_save_CFLAGS"
  LIBS="$ac_save_LIBS"
fi
AC_SUBST([XRANDR_CFLAGS])
AC_SUBST([XRANDR_LIBS])

dnl ***********************************
dnl *** Check for Xxf86vm extension ***
dnl ***********************************
AC_ARG_ENABLE([xf86vm],
AC_HELP_STRING([--enable-xf86vm], [try to use the Xxf86vm extension])
AC_HELP_STRING([--disable-xf86vm], [don't try to use the Xxf86vm extension]),
  [], [enable_xf86vm=yes])
XF86VM_CFLAGS= XF86VM_LIBS=
if test x"$enable_xf86vm" = x"yes"; then
  ac_save_CFLAGS="$CFLAGS"
  ac_save_LIBS="$LIBS"
  CFLAGS="$CFLAGS $CPPFLAGS $LIBX11_CFLAGS"
  LIBS="$LIBS $LIBX11_LDFLAGS $LIBX11_LIBS -lXext -lXxf86vm"
  AC_MSG_CHECKING([whether we can use the Xxf86vm extension])
  AC_TRY_LINK(
  [
#include <X11/Xlib.h>
#include <X11/extensions/xf86vmode.h>
  ], [XF86VidModeSetGamma((void *)0, 0, (void *)0);],
  [
    XF86VM_CFLAGS="-DUSE_XF86VM"
    XF86VM_LIBS="-lXext -lXxf86vm"
    AC_MSG_RESULT([yes])
  ], [ AC_MSG_RESULT([no]) ])
  CFLAGS="$ac_save_CFLAGS"
  LIBS="$ac_save_LIBS"
fi
AC_SUBST([XF86VM_CFLAGS])
AC_SUBST([XF86VM_LIBS])

dnl ****************************************
dnl *** Check for Xcursor (mouse plugin) ***
dnl ****************************************
ac_save_CFLAGS="$CFLAGS"
ac_save_LIBS="$LIBS"
CFLAGS="$CFLAGS $LIBX11_CFLAGS"
LIBS="$LIBS $LIBX11_LDFLAGS $LIBX11_LIBS -lXcursor"
XCURSOR_LIBS=
AC_CHECK_LIB([Xcursor], [XcursorGetDefaultSize],
[
  XCURSOR_LIBS="-lXcursor"
  AC_DEFINE([HAVE_XCURSOR_EXTENSION], [1], [Define if XCURSOR is present])
])
CFLAGS="$ac_save_CFLAGS"
LIBS="$ac_save_LIBS"
AC_SUBST([XCURSOR_LIBS])

dnl ***********************************
dnl *** Check for required packages ***
dnl ***********************************
XDT_CHECK_PACKAGE([GTK], [gtk+-2.0], [2.6.0])
XDT_CHECK_PACKAGE([LIBXFCEGUI4], [libxfcegui4-1.0], [4.4.0])

dnl **********************************
dnl *** Check for xfce-mcs-manager ***
dnl **********************************
XDT_XFCE_MCS_PLUGIN([XFCE_MCS_MANAGER], [4.4.0])

dnl ***********************************
dnl *** Xfce MCS plugin API version ***
dnl ***********************************
MCS_PLUGIN_API_VERSION=1
AC_SUBST([MCS_PLUGIN_API_VERSION])

dnl ***********************************
dnl *** Check for debugging support ***
dnl ***********************************
AC_ARG_ENABLE([debug],
AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes/full@:>@], [Turn on debugging @<:@default=xfce_mcs_plugins_debug_default@:>@]),
  [], [enable_debug=xfce_mcs_plugins_debug_default])
AC_MSG_CHECKING([whether to enable debugging support])
if test x"$enable_debug" = x"full" -o x"$enable_debug" = x"yes"; then
  dnl Check whether the compiler accepts the -errwarn=%all
  save_CFLAGS="$CFLAGS"
  CFLAGS="$CFLAGS -errwarn=%all"
  AC_MSG_CHECKING([whether $CC accepts -errwarn=%all])
  AC_COMPILE_IFELSE(AC_LANG_SOURCE([int x;]), [
    AC_MSG_RESULT([yes])
    PLATFORM_CFLAGS="$PLATFORM_CFLAGS -errwarn=%all"
  ], [
    AC_MSG_RESULT([no])
  ])
  CFLAGS="$save_CFLAGS"

  dnl Check whether the compiler accepts the -Werror
  save_CFLAGS="$CFLAGS"
  CFLAGS="$CFLAGS -Werror"
  AC_MSG_CHECKING([whether $CC accepts -Werror])
  AC_COMPILE_IFELSE(AC_LANG_SOURCE([int x;]), [
    AC_MSG_RESULT([yes])
    PLATFORM_CFLAGS="$PLATFORM_CFLAGS -Werror"
  ], [
    AC_MSG_RESULT([no])
  ])
  CFLAGS="$save_CFLAGS"

  dnl Check whether the compiler accepts the -Wall
  save_CFLAGS="$CFLAGS"
  CFLAGS="$CFLAGS -Wall"
  AC_MSG_CHECKING([whether $CC accepts -Wall])
  AC_COMPILE_IFELSE(AC_LANG_SOURCE([int x;]), [
    AC_MSG_RESULT([yes])
    PLATFORM_CFLAGS="$PLATFORM_CFLAGS -Wall"
  ], [
    AC_MSG_RESULT([no])
  ])
  CFLAGS="$save_CFLAGS"

  dnl Check whether the compiler accepts the -fno-strict-aliasing
  dnl switch, as certain packages - like Glib - still don't work
  dnl properly with newer compilers.
  save_CFLAGS="$CFLAGS"
  CFLAGS="$CFLAGS -fno-strict-aliasing"
  AC_MSG_CHECKING([whether $CC accepts -fno-strict-aliasing])
  AC_COMPILE_IFELSE(AC_LANG_SOURCE([int x;]), [
    AC_MSG_RESULT([yes])
    PLATFORM_CFLAGS="$PLATFORM_CFLAGS -fno-strict-aliasing"
  ], [
    AC_MSG_RESULT([no])
  ])
  CFLAGS="$save_CFLAGS"

  dnl Make sure we detect possible errors
  PLATFORM_CFLAGS="$PLATFORM_CFLAGS -Werror -Wall"

  dnl Paranoia for --enable-debug=full
  if test x"$enable_debug" = x"full"; then
    PLATFORM_CFLAGS="$PLATFORM_CFLAGS -O0 -g3"
    PLATFORM_CPPFLAGS="$PLATFORM_CPPFLAGS -DG_ENABLE_DEBUG"
  fi
else
  dnl Disable object cast checks
  PLATFORM_CPPFLAGS="$PLATFORM_CPPFLAGS -DG_DISABLE_CAST_CHECKS"

  dnl Disable all checks for --enable-debug=no
  if test x"$enable_debug" = x"no"; then
    PLATFORM_CPPFLAGS="$PLATFORM_CPPFLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
  fi
fi
AC_MSG_RESULT([$enable_debug])

dnl **************************************
dnl *** Check for linker optimizations ***
dnl **************************************
AC_MSG_CHECKING([whether $LD accepts -O1])
case `$LD -O1 -v 2>&1 </dev/null` in
*GNU* | *'with BFD'*)
  PLATFORM_LDFLAGS="$PLATFORM_LDFLAGS -Wl,-O1"
  AC_MSG_RESULT([yes])
  ;;
*)
  AC_MSG_RESULT([no])
  ;;
esac

dnl *********************************
dnl *** Substitute platform flags ***
dnl *********************************
AC_MSG_CHECKING([PLATFORM_CPPFLAGS])
AC_MSG_RESULT([$PLATFORM_CPPFLAGS])
AC_SUBST([PLATFORM_CPPFLAGS])
AC_MSG_CHECKING([PLATFORM_CFLAGS])
AC_MSG_RESULT([$PLATFORM_CFLAGS])
AC_SUBST([PLATFORM_CFLAGS])
AC_MSG_CHECKING([PLATFORM_LDFLAGS])
AC_MSG_RESULT([$PLATFORM_LDFLAGS])
AC_SUBST([PLATFORM_LDFLAGS])

XDT_FEATURE_DEBUG

AC_OUTPUT([
Makefile
doc/Makefile
doc/C/Makefile
doc/C/images/Makefile
doc/fr/Makefile
doc/fr/images/Makefile
doc/it/Makefile
doc/it/images/Makefile
icons/Makefile
icons/48x48/Makefile
icons/scalable/Makefile
po/Makefile.in 
plugins/Makefile
plugins/display_plugin/Makefile
plugins/gtk_common/Makefile
plugins/fm_plugin/Makefile
plugins/keyboard_plugin/Makefile
plugins/mouse_plugin/Makefile
plugins/screensaver_plugin/Makefile
plugins/ui_plugin/Makefile
xfce-mcs-plugins.spec
])