~ubuntu-branches/ubuntu/precise/libgrip/precise

#

# shamelessly stolen from clutter-gtk

#

m4_define([grip_major_version], [0])

m4_define([grip_minor_version], [3])

m4_define([grip_micro_version], [0])

m4_define([grip_api_version],

          [grip_major_version.grip_minor_version])

m4_define([grip_version],

          [grip_major_version.grip_minor_version.grip_micro_version])

m4_define([grip_interface_age], [0])

m4_define([grip_binary_age],

          [m4_eval(100 * grip_minor_version + grip_micro_version)])

AC_PREREQ(2.59)

AC_INIT([grip],

        [grip_version],

        [https://bugs.launchpad.net/libgrip])

AC_CONFIG_SRCDIR([src/grip.h])

AC_CONFIG_MACRO_DIR([m4])

AM_CONFIG_HEADER([config.h])

AM_INIT_AUTOMAKE([1.11 silent-rules])

AM_SILENT_RULES([yes])

AM_MAINTAINER_MODE

AM_PATH_PYTHON

GRIP_MAJOR_VERSION=grip_major_version

GRIP_MINOR_VERSION=grip_minor_version

GRIP_MICRO_VERSION=grip_micro_version

GRIP_VERSION=grip_version

AC_SUBST(GRIP_MAJOR_VERSION)

AC_SUBST(GRIP_MINOR_VERSION)

AC_SUBST(GRIP_MICRO_VERSION)

AC_SUBST(GRIP_VERSION)

m4_define([lt_current],

          [m4_eval(100 * grip_minor_version + grip_micro_version - grip_interface_age)])

m4_define([lt_revision], [grip_interface_age])

m4_define([lt_age], [m4_eval(grip_binary_age - grip_interface_age)])

GRIP_LT_CURRENT=lt_current

GRIP_LT_REV=lt_revision

GRIP_LT_AGE=lt_age

GRIP_LT_VERSION="$GRIP_LT_CURRENT:$GRIP_LT_REV:$GRIP_LT_AGE"

GRIP_LT_LDFLAGS="-version-info $GRIP_LT_VERSION"

AC_SUBST(GRIP_LT_VERSION)

AC_SUBST(GRIP_LT_LDFLAGS)

dnl ===========================================================================

# Checks for programs

AC_PROG_CC

AC_DISABLE_STATIC

AC_PROG_LIBTOOL

AC_PATH_PROG([GLIB_MKENUMS], [glib-mkenums])

# Checks for header files

AC_HEADER_STDC

AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h])

# Checks for typedefs, structures and compiler charecteristics

AC_C_CONST

# Checks for library functions

AC_FUNC_MALLOC

AC_FUNC_MMAP

AC_CHECK_FUNCS([memset munmap strcasecmp strdup])

PKG_CHECK_MODULES(GTK, gtk+-3.0 >= 3.0.8)

AC_SUBST(GTK_CFLAGS)

AC_SUBST(GTK_LIBS)

PKG_CHECK_MODULES(GEIS, libutouch-geis >= 2.1.1)

AC_SUBST(GEIS_CFLAGS)

AC_SUBST(GEIS_LIBS)

GOBJECT_INTROSPECTION_CHECK([0.6.7])

dnl ===========================================================================

if test "x$GCC" = "xyes"; then

  GCC_FLAGS="-g -Wall"

fi

AC_SUBST(GCC_FLAGS)

# use strict compiler flags only on development releases

m4_define([maintainer_flags_default], [m4_if(m4_eval(grip_minor_version % 2), [1], [yes], [no])])

AC_ARG_ENABLE([maintainer-flags],

              [AC_HELP_STRING([--enable-maintainer-flags=@<:@no/yes@:>@],

                              [Use strict compiler flags @<:@default=no@:>@])],

              [],

              [enable_maintainer_flags=maintainer_flags_default])

MAINTAINER_CFLAGS=""

AS_IF([test "x$enable_maintainer_flags" = "xyes" && test "x$GCC" = "xyes"],

      [

        MAINTAINER_CFLAGS="-Werror -Wall -Wshadow -Wcast-align -Wno-uninitialized -Wempty-body -Wformat-security -Winit-self"

      ]

)

AC_SUBST(MAINTAINER_CFLAGS)

dnl = GTK Doc Check ===========================================================

GTK_DOC_CHECK([1.8])

dnl ===========================================================================

AC_CONFIG_FILES([

  Makefile

  src/Makefile

  bindings/python/Makefile

  bindings/Makefile

  examples/rectangle-mover/Makefile

  libgrip.pc

  doc/Makefile

  doc/reference/Makefile

  doc/reference/libgrip-docs.sgml

])

AC_OUTPUT

echo ""

echo " grip $VERSION"

echo " ==============================="

echo ""

echo " Prefix       : ${prefix}"

echo ""

echo " Documentation: ${enable_gtk_doc}"

echo ""