~ubuntu-branches/ubuntu/trusty/sblim-sfcb/trusty-proposed

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
%option never-interactive
%{

/*
 * queryLexer.l
 *
 * (C) Copyright IBM Corp. 2005
 *
 * THIS FILE IS PROVIDED UNDER THE TERMS OF THE ECLIPSE PUBLIC LICENSE
 * ("AGREEMENT"). ANY USE, REPRODUCTION OR DISTRIBUTION OF THIS FILE
 * CONSTITUTES RECIPIENTS ACCEPTANCE OF THE AGREEMENT.
 *
 * You can obtain a current copy of the Eclipse Public License from
 * http://www.opensource.org/licenses/eclipse-1.0.php
 *
 * Author:        Adrian Schuur <schuur@de.ibm.com>
 * Based on concepts from pegasus project 
 *
 * Description:
 *
 * WQL/CQL query lexer for sfcb.
 *
*/

//%2005////////////////////////////////////////////////////////////////////////
//
// Copyright (c) 2000, 2001, 2002 BMC Software; Hewlett-Packard Development
// Company, L.P.; IBM Corp.; The Open Group; Tivoli Systems.
// Copyright (c) 2003 BMC Software; Hewlett-Packard Development Company, L.P.;
// IBM Corp.; EMC Corporation, The Open Group.
// Copyright (c) 2004 BMC Software; Hewlett-Packard Development Company, L.P.;
// IBM Corp.; EMC Corporation; VERITAS Software Corporation; The Open Group.
// Copyright (c) 2005 Hewlett-Packard Development Company, L.P.; IBM Corp.;
// EMC Corporation; VERITAS Software Corporation; The Open Group.
//
// Permission is hereby granted, free of charge, to any person obtaining a copy
// of this software and associated documentation files (the "Software"), to
// deal in the Software without restriction, including without limitation the
// rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
// sell copies of the Software, and to permit persons to whom the Software is
// furnished to do so, subject to the following conditions:
// 
// THE ABOVE COPYRIGHT NOTICE AND THIS PERMISSION NOTICE SHALL BE INCLUDED IN
// ALL COPIES OR SUBSTANTIAL PORTIONS OF THE SOFTWARE. THE SOFTWARE IS PROVIDED
// "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT
// LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR
// PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
// HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
// ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
// WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
//
///////////////////////////////////////////////////////////////////////////////


extern int queryInput(char* buffer, int* numRead, int numRequested);
extern int yyErr(const char*);
extern char * yyStrcpy(char *txt, int len);

#define YY_INPUT(BUF, NREAD, NREQUESTED) queryInput(BUF, &NREAD, NREQUESTED)

#include "queryOperation.h"
#include "queryParser.h"
#include <stdio.h>
#include <string.h>

%} 

POSITIVE_DECIMAL_DIGIT [1-9]
DECIMAL_DIGIT [0-9]
BLANK [ \t\n]
IDENT_CHAR [A-Za-z_]

%option nounput

%%

[Ss][Ee][Ll][Ee][Cc][Tt] {

    return TOK_SELECT;
}

[Ff][Rr][Oo][Mm] {

    return TOK_FROM;
}

[Ww][Hh][Ee][Rr][Ee] {

    return TOK_WHERE;
}

[Tt][Rr][Uu][Ee] {

    return TOK_TRUE;
}

[Ff][Aa][Ll][Ss][Ee] {

    return TOK_FALSE;
}

[Nn][Uu][Ll][Ll] {

    return TOK_NULL;
}

[Nn][Oo][Tt] {

    return TOK_NOT;
}

[Aa][Nn][Dd] {

    return TOK_AND;
}

[Oo][Rr] {

    return TOK_OR;
}

[Ii][Ss][Aa] {

    return TOK_ISA;
}

[Ii][Ss] {

    return TOK_IS;
}

[-+]?{POSITIVE_DECIMAL_DIGIT}{DECIMAL_DIGIT}* {

    yylval.intValue = strtol(yytext, (char**)0, 10);
    return TOK_INTEGER;
}

[+-]?0 {

    yylval.intValue = 0;
    return TOK_INTEGER;
}

[-+]?{DECIMAL_DIGIT}*\.{DECIMAL_DIGIT}+([eE][+-]?{DECIMAL_DIGIT}+)? {

    yylval.doubleValue = strtod((char*)yytext, (char**)0);
    return TOK_DOUBLE;
}

\'[^\'\n]*\' {

    {
       size_t n = strlen(yytext) - 2;
       yylval.strValue=yyStrcpy(yytext+1,n);
    }

    return TOK_STRING;
}

\'[^\'\n]*$ {

    yyErr("Unterminated string");
}

\"[^\"\n]*\" {

    {
       size_t n = strlen(yytext) - 2;
       yylval.strValue=yyStrcpy(yytext+1,n);
    }

    return TOK_STRING;
}

\"[^\"\n]*$ {

    yyErr("Unterminated string");
}

[\*(),.] { 

    return yytext[0];
}

"=" { 
    return TOK_EQ; 
}

"!=" { 

    return TOK_NE; 
}


"<>" { 
    return TOK_NE; 
}

"<=" { 
    return TOK_LE; 
}

"<" { 
    return TOK_LT; 
}

">=" { 
    return TOK_GE; 
}

">" { 
    return TOK_GT; 
}

"::" { 
    return TOK_SCOPE; 
}

{IDENT_CHAR}({IDENT_CHAR}|{DECIMAL_DIGIT})*  {

    {
	size_t n = strlen(yytext);
	yylval.strValue=yyStrcpy(yytext,n);
    }

    return TOK_IDENTIFIER;
}

{BLANK}+ {
    /* Ignore blanks */
}

. {
    yylval.intValue = 0;
    return TOK_UNEXPECTED_CHAR;
}

%%

int yywrap()
{
    return 1;
}