1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
|
<!--
Copyright © 2007 Dennis Kasprzyk
Permission to use, copy, modify, distribute, and sell this software
and its documentation for any purpose is hereby granted without
fee, provided that the above copyright notice appear in all copies
and that both that copyright notice and this permission notice
appear in supporting documentation, and that the name of
Dennis Kasprzyk not be used in advertising or publicity pertaining to
distribution of the software without specific, written prior permission.
Dennis Kasprzyk makes no representations about the suitability of this
software for any purpose. It is provided "as is" without express or
implied warranty.
DENNIS KASPRZYK DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN
NO EVENT SHALL DENNIS KASPRZYK BE LIABLE FOR ANY SPECIAL, INDIRECT OR
CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS
OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT,
NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION
WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
Authors: Dennis Kasprzyk <onestone@deltatauchi.de>
-->
<xsl:stylesheet version='1.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform' >
<xsl:output method="xml" indent="yes"/>
<xsl:param name="appName">/apps/compiz-1</xsl:param>
<xsl:template match="/compiz">
<gconfschemafile>
<schemalist>
<!-- two levels of indentation: group and subgroup>= -->
<xsl:for-each select="/compiz//options//option[not(@read_only='true') and not(@type='action')]">
<xsl:call-template name="dumpOption"/>
</xsl:for-each>
</schemalist>
</gconfschemafile>
</xsl:template>
<!-- generates the schema for an option -->
<xsl:template name="dumpOption">
<schema>
<key>/schemas<xsl:call-template name="printKey"/></key>
<applyto><xsl:call-template name="printKey"/></applyto>
<owner>compiz-1</owner>
<type><xsl:call-template name="printType"/></type>
<xsl:choose>
<!-- color values need a special handling -->
<xsl:when test="@type = 'color'">
<default>
<xsl:choose>
<xsl:when test="default">
<xsl:for-each select="default[1]">
<xsl:call-template name="printColor"/>
</xsl:for-each>
</xsl:when>
<xsl:otherwise>
<xsl:text>#000000ff</xsl:text>
</xsl:otherwise>
</xsl:choose>
</default>
</xsl:when>
<xsl:when test="@type = 'edge'">
<default>
<xsl:call-template name="printEdgeList"/>
</default>
</xsl:when>
<xsl:when test="@type = 'list'">
<list_type>
<xsl:call-template name="printType">
<xsl:with-param name="type" select="type/text()"/>
</xsl:call-template>
</list_type>
<xsl:choose>
<xsl:when test="type/text() = 'color'">
<default>[<xsl:call-template name="printColorList"/>]</default>
</xsl:when>
<xsl:otherwise>
<default>[<xsl:call-template name="printValueList"/>]</default>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
<!-- for most option types we can use the default value directly -->
<xsl:otherwise>
<default>
<xsl:choose>
<xsl:when test="default/text()">
<xsl:value-of select="default/text()"/>
</xsl:when>
<xsl:otherwise>
<!-- if no default value was specified we need to generate one -->
<xsl:choose>
<xsl:when test="contains('bool,bell',@type)">
<xsl:text>false</xsl:text>
</xsl:when>
<xsl:when test="@type = 'int'">
<xsl:variable name="num">
<xsl:call-template name="printNumFallback"/>
</xsl:variable>
<xsl:value-of select="floor($num)"/>
</xsl:when>
<xsl:when test="@type = 'float'">
<xsl:call-template name="printNumFallback"/>
</xsl:when>
<xsl:when test="contains('key,button',@type)">
<xsl:text>Disabled</xsl:text>
</xsl:when>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
</default>
</xsl:otherwise>
</xsl:choose>
<!-- add the short and long descriptions -->
<xsl:call-template name="printDescription"/>
</schema>
</xsl:template>
<!-- converts a compiz type to a gconf type -->
<xsl:template name="printType">
<xsl:param name="type">
<xsl:value-of select="@type"/>
</xsl:param>
<xsl:choose>
<xsl:when test="$type = 'int'">
<xsl:text>int</xsl:text>
</xsl:when>
<xsl:when test="$type = 'float'">
<xsl:text>float</xsl:text>
</xsl:when>
<xsl:when test="$type = 'bool'">
<xsl:text>bool</xsl:text>
</xsl:when>
<xsl:when test="$type = 'list'">
<xsl:text>list</xsl:text>
</xsl:when>
<xsl:when test="$type = 'bell'">
<xsl:text>bool</xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:text>string</xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!-- prints the option long and short descriptions of an option -->
<xsl:template name="printDescription">
<xsl:param name="info">
<xsl:call-template name="printInfo"/>
</xsl:param>
<locale name="C">
<short><xsl:value-of select="short[not(@xml:lang)]/text()"/></short>
<long>
<xsl:value-of select="long[not(@xml:lang)]/text()"/>
<xsl:value-of select="$info"/>
</long>
</locale>
<xsl:for-each select="short[@xml:lang]">
<xsl:variable name="language" select="@xml:lang"/>
<xsl:variable name="infoTrans">
<xsl:call-template name="printInfoTrans">
<xsl:with-param name="language" select="$language"/>
</xsl:call-template>
</xsl:variable>
<locale>
<xsl:attribute name='name'>
<xsl:value-of select="@xml:lang"/>
</xsl:attribute>
<short><xsl:value-of select="text()"/></short>
<long>
<xsl:choose>
<xsl:when test="parent::option/long[lang($language)]">
<xsl:value-of select="parent::option/long[lang($language)]/text()"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="parent::option/long[not(@xml:lang)]/text()"/>
</xsl:otherwise>
</xsl:choose>
<xsl:value-of select="$infoTrans"/>
</long>
</locale>
</xsl:for-each>
</xsl:template>
<!-- generates the additional info for the long option description -->
<xsl:template name="printInfo">
<xsl:variable name="info">
<xsl:text> (</xsl:text>
<xsl:choose>
<xsl:when test="contains('int,float',@type) and not(desc/value/text())">
<xsl:value-of select="min/text()"/> - <xsl:value-of select="max/text()"/>
</xsl:when>
<xsl:when test="@type='int' and desc/value/text()">
<xsl:call-template name="printIntDescList"/>
</xsl:when>
<xsl:when test="@type = 'match'">
<xsl:text>match</xsl:text>
</xsl:when>
</xsl:choose>
<xsl:text>)</xsl:text>
</xsl:variable>
<xsl:if test="not(contains($info,' ()'))">
<xsl:value-of select="$info"/>
</xsl:if>
</xsl:template>
<!-- generates a list of int descriptions -->
<xsl:template name="printIntDescList">
<xsl:variable name="list">
<xsl:for-each select="desc">
<xsl:value-of select="value/text()"/>
<xsl:text> = </xsl:text>
<xsl:value-of select="name/text()"/>
<xsl:text>, </xsl:text>
</xsl:for-each>
</xsl:variable>
<xsl:value-of select="substring($list,1,string-length($list) - 2)"/>
</xsl:template>
<!-- generates the additional info for the long option description -->
<xsl:template name="printInfoTrans">
<xsl:param name="language"/>
<xsl:variable name="info">
<xsl:text> (</xsl:text>
<xsl:choose>
<xsl:when test="contains('int,float',parent::option/@type) and not(parent::option/desc/value/text())">
<xsl:value-of select="parent::option/min/text()"/> - <xsl:value-of select="parent::option/max/text()"/>
</xsl:when>
<xsl:when test="parent::option/@type='int' and parent::option/desc/value/text()">
<xsl:call-template name="printIntDescListTrans">
<xsl:with-param name="language" select="$language"/>
</xsl:call-template>
</xsl:when>
<xsl:when test="parent::option/@type = 'match'">
<xsl:text>match</xsl:text>
</xsl:when>
</xsl:choose>
<xsl:text>)</xsl:text>
</xsl:variable>
<xsl:if test="not(contains($info,' ()'))">
<xsl:value-of select="$info"/>
</xsl:if>
</xsl:template>
<!-- generates a list of int descriptions -->
<xsl:template name="printIntDescListTrans">
<xsl:param name="language"/>
<xsl:variable name="list">
<xsl:for-each select="parent::option/desc">
<xsl:value-of select="value/text()"/>
<xsl:text> = </xsl:text>
<xsl:choose>
<xsl:when test="name[lang($language)]/text()">
<xsl:value-of select="name[lang($language)]/text()"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="name[not(@xml:lang)]/text()"/>
</xsl:otherwise>
</xsl:choose>
<xsl:text>, </xsl:text>
</xsl:for-each>
</xsl:variable>
<xsl:value-of select="substring($list,1,string-length($list) - 2)"/>
</xsl:template>
<!-- generates a default number out of the min and max values -->
<xsl:template name="printNumFallback">
<xsl:choose>
<xsl:when test="max/text() and min/text()">
<xsl:value-of select="(max/text() + min/text()) div 2"/>
</xsl:when>
<xsl:when test="max/text() and not(min/text())">
<xsl:value-of select="max/text()"/>
</xsl:when>
<xsl:when test="not(max/text()) and min/text()">
<xsl:value-of select="min/text()"/>
</xsl:when>
<xsl:otherwise>0</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!-- generates a list of values -->
<xsl:template name="printValueList">
<xsl:variable name="list">
<xsl:for-each select="default/value">
<xsl:value-of select="text()"/>
<xsl:text>,</xsl:text>
</xsl:for-each>
</xsl:variable>
<xsl:value-of select="substring($list,1,string-length($list) - 1)"/>
</xsl:template>
<!-- generates a list of color string values -->
<xsl:template name="printColorList">
<xsl:variable name="list">
<xsl:for-each select="default/value">
<xsl:call-template name="printColor"/>
<xsl:text>,</xsl:text>
</xsl:for-each>
</xsl:variable>
<xsl:value-of select="substring($list,1,string-length($list) - 1)"/>
</xsl:template>
<!--
generates the #00aabbcc color value out of the compiz
metadata color description
-->
<xsl:template name="printColor">
<xsl:variable name="red">
<xsl:call-template name="getHexNum">
<xsl:with-param name="value" select="red/text()"/>
</xsl:call-template>
</xsl:variable>
<xsl:variable name="green">
<xsl:call-template name="getHexNum">
<xsl:with-param name="value" select="green/text()"/>
</xsl:call-template>
</xsl:variable>
<xsl:variable name="blue">
<xsl:call-template name="getHexNum">
<xsl:with-param name="value" select="blue/text()"/>
</xsl:call-template>
</xsl:variable>
<xsl:variable name="alpha">
<xsl:choose>
<xsl:when test="alpha/text()">
<xsl:call-template name="getHexNum">
<xsl:with-param name="value" select="alpha/text()"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:text>ff</xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:value-of select="concat('#',concat($red,concat($green,concat($blue,$alpha))))"/>
</xsl:template>
<!--
converts a decimal number in the range of 0-65535 or
a hex number in the range of 0x0000 - 0xffff to a hex number in the
range of 00 - ff
-->
<xsl:template name="getHexNum">
<xsl:param name="value"/>
<xsl:choose>
<xsl:when test="starts-with($value,'0x')">
<xsl:variable name="number">
<xsl:text>0000</xsl:text>
<xsl:value-of select="substring-after($value,'0x')"/>
</xsl:variable>
<xsl:value-of select="substring(concat('000',$number),string-length($number),2)"/>
</xsl:when>
<xsl:when test="string-length($value)">
<xsl:variable name="number">
<xsl:call-template name="toHex">
<xsl:with-param name="decimalNumber" select="$value"/>
</xsl:call-template>
</xsl:variable>
<xsl:value-of select="substring(concat('000',$number),string-length($number),2)"/>
</xsl:when>
<xsl:otherwise>
<xsl:text>00</xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!-- generates a list of selected edges -->
<xsl:template name="printEdgeList">
<xsl:variable name="list">
<xsl:for-each select="default/edge">
<xsl:value-of select="@name"/>
<xsl:text> | </xsl:text>
</xsl:for-each>
</xsl:variable>
<xsl:value-of select="substring($list,1,string-length($list) - 3)"/>
</xsl:template>
<!-- prints the key path for an option -->
<xsl:template name="printKey">
<xsl:value-of select="$appName"/>
<xsl:choose>
<xsl:when test="ancestor::plugin">
<xsl:text>/plugins/</xsl:text>
<xsl:value-of select="ancestor::plugin/@name"/>
</xsl:when>
<xsl:otherwise>
<xsl:text>/general</xsl:text>
</xsl:otherwise>
</xsl:choose>
<xsl:text>/screen0/options/</xsl:text>
<xsl:value-of select="@name"/>
</xsl:template>
<!-- converts a decimal number to a hex number -->
<xsl:variable name="hexDigits" select="'0123456789abcdef'" />
<xsl:template name="toHex">
<xsl:param name="decimalNumber" />
<xsl:if test="$decimalNumber >= 16">
<xsl:call-template name="toHex">
<xsl:with-param name="decimalNumber" select="floor($decimalNumber div 16)" />
</xsl:call-template>
</xsl:if>
<xsl:value-of select="substring($hexDigits, ($decimalNumber mod 16) + 1, 1)" />
</xsl:template>
</xsl:stylesheet>
|