~ubuntu-branches/debian/squeeze/ffcall/squeeze

dnl -*- Autoconf -*-

dnl Copyright (C) 1993-2004 Free Software Foundation, Inc.

dnl This file is free software, distributed under the terms of the GNU

dnl General Public License.  As a special exception to the GNU General

dnl Public License, this file may be distributed as part of a program

dnl that contains a configuration script generated by Autoconf, under

dnl the same distribution terms as the rest of that program.

 

dnl From Bruno Haible, Marcus Daniels, Sam Steingold.

 

AC_PREREQ(2.57)

 

AC_DEFUN([CL_TCPCONN],

[CL_COMPILE_CHECK([IPv4 sockets], cl_cv_socket_ipv4,

[#include <sys/types.h>

#include <sys/socket.h>

#include <netinet/in.h>],

[int x = AF_INET; struct in_addr y; struct sockaddr_in z;],

AC_DEFINE(HAVE_IPV4,,[<sys/socket.h> defines AF_INET]))

CL_COMPILE_CHECK([IPv6 sockets], cl_cv_socket_ipv6,

[#include <sys/types.h>

#include <sys/socket.h>

#include <netinet/in.h>],

[int x = AF_INET6; struct in6_addr y; struct sockaddr_in6 z;],

AC_DEFINE(HAVE_IPV6,,[<sys/socket.h> defines AF_INET6]))

if test $cl_cv_socket_ipv6 = no; then

CL_COMPILE_CHECK([IPv6 sockets in linux/in6.h], cl_cv_socket_ipv6_linux,

[#include <sys/types.h>

#include <sys/socket.h>

#include <netinet/in.h>

#include <linux/in6.h>],

[int x = AF_INET6; struct in6_addr y; struct sockaddr_in6 z;],

AC_DEFINE(IPV6_NEED_LINUX_IN6_H,,[need <linux/in6.h> for the in6_addr and sockaddr_in6 types])

AC_DEFINE(HAVE_IPV6))

fi

AC_CHECK_FUNCS(inet_pton inet_ntop inet_addr setsockopt getsockopt)

AC_CHECK_HEADERS(netinet/in.h arpa/inet.h)dnl

if test $ac_cv_func_inet_addr = yes; then

CL_PROTO([inet_addr], [

for x in '' 'const'; do

for y in 'struct in_addr' 'unsigned long' 'unsigned int'; do

if test -z "$have_inet_addr"; then

CL_PROTO_TRY([

#ifdef HAVE_UNISTD_H

#include <unistd.h>

#endif

#include <sys/types.h>

#include <netinet/in.h>

#ifdef HAVE_ARPA_INET_H

#include <arpa/inet.h>

#endif

#ifdef __BEOS__

#include <sys/socket.h>

#include <netdb.h>

#endif

], [$y inet_addr ($x char *);], [$y inet_addr();], [

cl_cv_proto_inet_addr_ret="$y"

cl_cv_proto_inet_addr_arg1="$x"

have_inet_addr=1])

fi

done

done

if test -z "$have_inet_addr"; then

  echo "*** Missing autoconfiguration support for this platform." 1>&2

  echo "*** Please report this as a bug to the CLISP developers." 1>&2

  echo "*** When doing this, please also show your system's inet_addr() declaration." 1>&2

  exit 1

fi

], [extern $cl_cv_proto_inet_addr_ret inet_addr ($cl_cv_proto_inet_addr_arg1 char*);])

AC_DEFINE_UNQUOTED(RET_INET_ADDR_TYPE,$cl_cv_proto_inet_addr_ret,[return type of inet_addr()])

AC_DEFINE_UNQUOTED(INET_ADDR_CONST,$cl_cv_proto_inet_addr_arg1,[declaration of inet_addr() needs const])

if test "$cl_cv_proto_inet_addr_ret" = "struct in_addr"; then

AC_DEFINE(INET_ADDR_SUFFIX,[.s_addr],[Define as .s_addr if the return type of inet_addr() is a struct type, as empty if it is a scalar type])

else

AC_DEFINE(INET_ADDR_SUFFIX,[])

fi

fi

AC_CHECK_HEADERS(netinet/tcp.h,,,

dnl AIX 4 requires <netinet/in.h> to be included before <netinet/tcp.h>.

[#if HAVE_NETINET_IN_H

#include <netinet/in.h>

#endif

])

if test $ac_cv_func_setsockopt = yes; then

CL_PROTO([setsockopt], [

for z in 'int' 'unsigned int' 'size_t'; do

for y in 'char*' 'void*'; do

for x in '' 'const'; do

if test -z "$have_setsockopt_decl"; then

CL_PROTO_TRY([

#include <sys/types.h>

#include <sys/socket.h>

], [int setsockopt (int, int, int, $x $y, $z);], [int setsockopt ();], [

cl_cv_proto_setsockopt_const="$x"

cl_cv_proto_setsockopt_arg_t="$y"

cl_cv_proto_setsockopt_optlen_t="$z"

have_setsockopt_decl=1])

fi

done

done

done

if test -z "$have_setsockopt_decl"; then

  echo "*** Missing autoconfiguration support for this platform." 1>&2

  echo "*** Please report this as a bug to the CLISP developers." 1>&2

  echo "*** When doing this, please also show your system's setsockopt() declaration." 1>&2

  exit 1

fi

], [extern int setsockopt (int, int, int, $cl_cv_proto_setsockopt_const $cl_cv_proto_setsockopt_arg_t, $cl_cv_proto_setsockopt_optlen_t);])

AC_DEFINE_UNQUOTED(SETSOCKOPT_CONST,$cl_cv_proto_setsockopt_const,[declaration of setsockopt() needs const])

AC_DEFINE_UNQUOTED(SETSOCKOPT_ARG_T,$cl_cv_proto_setsockopt_arg_t,[type of `optval' in setsockopt() declaration])

AC_DEFINE_UNQUOTED(SETSOCKOPT_OPTLEN_T,$cl_cv_proto_setsockopt_optlen_t,[type of `optlen' in setsockopt() declaration])

fi

])