← Back to branch summary

~ubuntu-branches/ubuntu/precise/vino/precise-proposed-201205170738

« back to all changes in this revision

Viewing changes to .pc/05_use-system-miniupnpc.patch/configure.ac

  • Committer: Package Import Robot
  • Author(s): Jeremy Bicha
  • Date: 2011-09-02 08:10:47 UTC
  • mfrom: (1.1.52 upstream)
  • Revision ID: package-import@ubuntu.com-20110902081047-vfofquvdgrnfyz2f
Tags: 3.1.90-0ubuntu1
* New upstream release.
* debian/control: Add libminiupnpc-dev to build dependencies
* debian/patches/05_use-system-miniupnpc.patch
  - Use system miniupnpc library, not the bundled copy

Show diffs side-by-side

added added

removed removed

Lines of Context:
.pc/05_use-system-miniupnpc.patch/configure.ac
 
1
AC_PREREQ([2.64])
 
2
AC_INIT([Vino], [3.1.90], [http://bugzilla.gnome.org/enter_bug.cgi?product=vino], [vino], [http://live.gnome.org/Vino])
 
3
AC_CONFIG_AUX_DIR([build-aux])
 
4
AC_CONFIG_SRCDIR([server/vino-fb.c])
 
5
AC_CONFIG_HEADERS([config.h])
 
6
AC_CONFIG_MACRO_DIR([m4])
 
7
 
 
8
AM_INIT_AUTOMAKE([1.11.1 -Wall check-news dist-xz no-define no-dist-gzip nostdinc subdir-objects])
 
9
AM_SILENT_RULES([yes])
 
10
 
 
11
AC_PROG_CC
 
12
AM_PROG_CC_C_O
 
13
 
 
14
# Check whether to enable HTTP server support
 
15
AC_ARG_ENABLE([http-server],
 
16
  [AS_HELP_STRING([--disable-http-server],
 
17
   [build with an HTTP server for serving a Java applet client @<:@default=yes@:>@])],
 
18
   [],
 
19
   [enable_http_server=yes])
 
20
 
 
21
AS_IF([test "x$enable_http_server" = "xyes"],
 
22
  [AC_DEFINE([VINO_ENABLE_HTTP_SERVER], [], [Enable HTTP server support])])
 
23
 
 
24
AM_CONDITIONAL([VINO_ENABLE_HTTP_SERVER], [test "x$enable_http_server" = "xyes"])
 
25
 
 
26
# GNOME common
 
27
GNOME_MAINTAINER_MODE_DEFINES
 
28
GNOME_COMPILE_WARNINGS([maximum])
 
29
GNOME_DEBUG_CHECK
 
30
 
 
31
LT_PREREQ([2.2.6])
 
32
LT_INIT([disable-static])
 
33
 
 
34
PKG_PROG_PKG_CONFIG([0.16])
 
35
 
 
36
AC_PROG_SED
 
37
 
 
38
AC_MSG_CHECKING([for glib-genmarshal script])
 
39
GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 
40
AS_IF([test "x$GLIB_GENMARSHAL" = "x"],
 
41
  [AC_MSG_ERROR([glib-genmarshal not listed in glib-2.0 pkg-config file])],
 
42
  [AC_SUBST([GLIB_GENMARSHAL])
 
43
    AC_MSG_RESULT([$GLIB_GENMARSHAL])])
 
44
 
 
45
AC_MSG_CHECKING([for glib-mkenums script])
 
46
GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
 
47
AS_IF([test "x$GLIB_MKENUMS" = "x"],
 
48
  [AC_MSG_ERROR([glib-mkenums not listed in glib-2.0 pkg-config file])],
 
49
  [AC_SUBST([GLIB_MKENUMS])
 
50
    AC_MSG_RESULT([$GLIB_MKENUMS])])
 
51
 
 
52
# Check for telepathy-glib
 
53
TELEPATHY_GLIB_DEPS="dbus-glib-1 telepathy-glib >= 0.11.6"
 
54
 
 
55
AC_ARG_WITH([telepathy],
 
56
  [AS_HELP_STRING([--without-telepathy],
 
57
    [ignore the presence of telepathy and disable it])])
 
58
 
 
59
AS_IF([test "x$with_telepathy" != "xno"],
 
60
  [PKG_CHECK_EXISTS([$TELEPATHY_GLIB_DEPS],
 
61
    [have_telepathy=yes],
 
62
    [have_telepathy=no])],
 
63
  [have_telepathy=no])
 
64
 
 
65
AS_IF([test "x$have_telepathy" = "xyes"],
 
66
  [AC_DEFINE([VINO_HAVE_TELEPATHY_GLIB], [], [Build with telepathy support])],
 
67
  [TELEPATHY_GLIB_DEPS=""
 
68
    AS_IF([test "x$with_telepathy" = "xyes"],
 
69
    [AC_MSG_ERROR([telepathy support requested but not found])])])
 
70
 
 
71
AM_CONDITIONAL([VINO_HAVE_TELEPATHY_GLIB], [test "x$have_telepathy" = "xyes"])
 
72
 
 
73
# Check for libnotify
 
74
LIBNOTIFY_DEPS="libnotify >= 0.4.4"
 
75
LIBNOTIFY_0_7_DEPS="libnotify >= 0.7.0"
 
76
 
 
77
AC_ARG_WITH([libnotify],
 
78
  [AS_HELP_STRING([--without-libnotify],
 
79
    [ignore the presence of libnotify and disable it])])
 
80
 
 
81
AS_IF([test "x$with_libnotify" != "xno"],
 
82
  [PKG_CHECK_EXISTS([$LIBNOTIFY_DEPS],
 
83
    [have_libnotify=yes],
 
84
    [have_libnotify=no])],
 
85
  [have_libnotify=no])
 
86
 
 
87
AS_IF([test "x$have_libnotify" = "xyes"],
 
88
  [AC_DEFINE([VINO_HAVE_LIBNOTIFY], [], [Build with libnotify support])
 
89
    PKG_CHECK_EXISTS([$LIBNOTIFY_0_7_DEPS],
 
90
      [have_libnotify_0_7=yes],
 
91
      [have_libnotify_0_7=no])
 
92
    AS_IF([test "x$have_libnotify_0_7" = "xyes"],
 
93
      [LIBNOTIFY_DEPS="$LIBNOTIFY_0_7_DEPS"
 
94
        AC_DEFINE([VINO_HAVE_LIBNOTIFY_0_7], [], [Build with libnotify 0.7 or greater support])])],
 
95
  [LIBNOTIFY_DEPS=""
 
96
    AS_IF([test "x$have_libnotify" = "xyes"],
 
97
    [AC_MSG_ERROR([libnotify support requested but not found])])])
 
98
 
 
99
# Check for NetworkManager
 
100
NETWORKMANAGER_DEPS="NetworkManager >= 0.7"
 
101
 
 
102
AC_ARG_WITH([network-manager],
 
103
  [AS_HELP_STRING([--without-network-manager],
 
104
    [ignore the presence of NetworkManager and disable it])])
 
105
 
 
106
AS_IF([test "x$with_network_manager" != "xno"],
 
107
  [PKG_CHECK_EXISTS([$NETWORKMANAGER_DEPS],
 
108
    [have_network_manager=yes],
 
109
    [have_network_manager=no])],
 
110
  [have_network_manager=no])
 
111
 
 
112
AS_IF([test "x$have_network_manager" = "xyes"],
 
113
  [AC_DEFINE([VINO_HAVE_NETWORKMANAGER], [], [Build with NetworkManager support])],
 
114
  [NETWORKMANAGER_DEPS=""
 
115
    AS_IF([test "x$with_network_manager" = "xyes"],
 
116
    [AC_MSG_ERROR([NetworkManager support requested but not found])])])
 
117
 
 
118
# Check for gnome-keyring
 
119
GNOME_KEYRING_DEPS="gnome-keyring-1"
 
120
 
 
121
AC_ARG_WITH([gnome-keyring],
 
122
  [AS_HELP_STRING([--without-gnome-keyring],
 
123
    [ignore the presence of gnome-keyring and disable it])])
 
124
 
 
125
AS_IF([test "x$with_gnome_keyring" != "xno"],
 
126
  [PKG_CHECK_EXISTS([$GNOME_KEYRING_DEPS],
 
127
    [have_gnome_keyring=yes],
 
128
    [have_gnome_keyring=no])],
 
129
  [have_gnome_keyring=no])
 
130
 
 
131
AS_IF([test "x$have_gnome_keyring" != "xno"],
 
132
  [AC_DEFINE([VINO_HAVE_GNOME_KEYRING], [], [Build with gnome-keyring support])],
 
133
  [GNOME_KEYRING_DEPS=""
 
134
    AS_IF([test "x$with_gnome_keyring" = "xyes"],
 
135
    [AC_MSG_ERROR([gnome-keyring support requested but not found])])])
 
136
 
 
137
# Check for X11
 
138
AC_PATH_XTRA
 
139
 
 
140
AS_IF([test "x$no_x" = "xyes"],
 
141
  [AC_MSG_ERROR([X development libraries not found])],
 
142
  [AC_SUBST([X_LIBS], ["$X_PRE_LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"])])
 
143
 
 
144
# Check for gnutls
 
145
GNUTLS_DEPS="gnutls >= 2.2.0"
 
146
 
 
147
AC_ARG_WITH([gnutls],
 
148
  [AS_HELP_STRING([--without-gnutls],
 
149
    [ignore gnutls support and disable it])])
 
150
 
 
151
AS_IF([test "x$with_gnutls" != "xno"],
 
152
  [PKG_CHECK_EXISTS([$GNUTLS_DEPS],
 
153
    [have_gnutls=yes],
 
154
    [have_gnutls=no])],
 
155
  [have_gnutls=no
 
156
    AC_MSG_WARN([gnutls was not found. You may want to get it from ftp://ftp.gnutls.org/pub/gnutls/])])
 
157
 
 
158
AS_IF([test "x$have_gnutls" = "xyes"],
 
159
  [AC_DEFINE([VINO_HAVE_GNUTLS], [], [Build with gnutls support])],
 
160
  [GNUTLS_DEPS=""
 
161
    AS_IF([test "x$with_gnutls" = "xyes"],
 
162
    [AC_MSG_ERROR([gnutls support was requested but not found])])])
 
163
 
 
164
# Check for gcrypt
 
165
GCRYPT_VERSION=1.1.90
 
166
 
 
167
AC_ARG_WITH([gcrypt],
 
168
  [AS_HELP_STRING([--without-gcrypt],
 
169
    [ignore gcrypt support and disable it])])
 
170
 
 
171
AS_IF([test "x$with_gcrypt" != "xno"],
 
172
  [AM_PATH_LIBGCRYPT([$GCRYPT_VERSION],
 
173
    [have_gcrypt=yes],
 
174
    [have_gcrypt=no])],
 
175
  [have_gcrypt=no
 
176
    AC_MSG_WARN([gcrypt was not found. You may want to get it from ftp://ftp.gnupg.org/pub/gcrypt/alpha/libgcrypt/])])
 
177
 
 
178
AS_IF([test "x$have_gcrypt" = "xyes"],
 
179
  [AC_DEFINE([VINO_HAVE_GCRYPT], [], [Build with gcrypt support])],
 
180
  [AS_IF([test "x$with_gcrypt" = "xyes"],
 
181
    [AC_MSG_ERROR([gcrypt support requested but not found])])])
 
182
 
 
183
# Check for Avahi
 
184
AVAHI_DEPS="avahi-client >= 0.6 avahi-glib >= 0.6"
 
185
 
 
186
AC_ARG_WITH([avahi],
 
187
  [AS_HELP_STRING([--without-avahi],
 
188
    [ignore avahi support and disable it])])
 
189
 
 
190
AS_IF([test "x$with_avahi" != "xno"],
 
191
  [PKG_CHECK_EXISTS([$AVAHI_DEPS],
 
192
    [have_avahi=yes],
 
193
    [have_avahi=no])],
 
194
  [have_avahi=no])
 
195
 
 
196
AS_IF([test "x$have_avahi" = "xyes"],
 
197
  [AC_DEFINE([VINO_HAVE_AVAHI], [], [Build with avahi support])],
 
198
  [AVAHI_DEPS=""
 
199
    AS_IF([test "x$with_avahi" = "xyes"],
 
200
    [AC_MSG_ERROR([avahi support requested but not found])])])
 
201
 
 
202
# Check for zlib
 
203
# TODO: Use pkg-config file installed by newer zlib releases
 
204
AC_ARG_WITH([zlib],
 
205
  [AS_HELP_STRING([--without-zlib],
 
206
    [ignore zlib support and disable it])])
 
207
 
 
208
AS_IF([test "x$with_zlib" != "xno"],
 
209
  [AC_CHECK_HEADER([zlib.h],
 
210
    [AC_CHECK_LIB([z], [deflate], [have_zlib=yes], [have_zlib=no])],
 
211
    [have_zlib=no])],
 
212
  [have_zlib=no])
 
213
 
 
214
AS_IF([test "x$have_zlib" = "xyes"],
 
215
  [AC_DEFINE([VINO_HAVE_ZLIB], [], [Build with zlib support])
 
216
    AC_SUBST([ZLIB_LIBS], [-lz])],
 
217
  [AS_IF([test "x$with_zlib" = "xyes"],
 
218
    [AC_MSG_ERROR([zlib support requested but not found])])])
 
219
 
 
220
# Check for jpeg, with deflate support
 
221
AC_ARG_WITH([jpeg],
 
222
  [AS_HELP_STRING([--without-jpeg],
 
223
    [ignore jpeg support and disable it])])
 
224
 
 
225
AS_IF([test "x$with_jpeg" != "xno"],
 
226
  [AC_CHECK_HEADER([jpeglib.h],
 
227
    [AC_CHECK_LIB([jpeg], [jpeg_CreateCompress], [have_jpeg=yes], [have_jpeg=no])],
 
228
    [have_jpeg=no])],
 
229
  [have_jpeg=no])
 
230
 
 
231
AS_IF([test "x$have_jpeg" = "xyes"],
 
232
  [AC_DEFINE([VINO_HAVE_JPEG], [], [Build with jpeg support])
 
233
    AC_SUBST([JPEG_LIBS], [-ljpeg])],
 
234
  [AS_IF([test "x$with_jpeg" = "xyes"],
 
235
    [AC_MSG_ERROR([jpeg support requested but not found])])])
 
236
 
 
237
# Internationalization
 
238
AC_SUBST([GETTEXT_PACKAGE],[$PACKAGE_TARNAME])
 
239
AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], ["$GETTEXT_PACKAGE"], [gettext package])
 
240
IT_PROG_INTLTOOL([0.40.0])
 
241
 
 
242
# Check for XDAMAGE extension
 
243
AC_CHECK_HEADER([X11/extensions/Xdamage.h],
 
244
  [AC_CHECK_LIB([Xdamage], [XDamageQueryExtension],
 
245
    [AC_DEFINE([VINO_HAVE_XDAMAGE], [], [Defined if the DAMAGE X extension is present])
 
246
      AC_SUBST([XDAMAGE_LIBS], ["-lXdamage -lXfixes"])],
 
247
    [], [$X_LIBS])],
 
248
  [], [#include <X11/Xlib.h>])
 
249
 
 
250
# Check for MIT-SHM extension
 
251
AC_CHECK_HEADER([X11/extensions/XShm.h],
 
252
  [AC_CHECK_LIB([Xext], [XShmQueryExtension],
 
253
    [AC_DEFINE([VINO_HAVE_XSHM], [], [Defined if the MIT-SHM X extension is present])
 
254
      AC_SUBST([XSHM_LIBS], [-lXext])],
 
255
    [], [$X_LIBS])],
 
256
  [], [#include <X11/Xlib.h>])
 
257
 
 
258
# Check for XTest extension
 
259
AC_CHECK_HEADER([X11/extensions/XTest.h],
 
260
  [AC_CHECK_LIB([Xtst], [XTestQueryExtension],
 
261
    [AC_DEFINE([VINO_HAVE_XTEST], [], [Defined if the XTEST X extension is present])
 
262
      AC_SUBST([XTEST_LIBS], [-lXtst])],
 
263
    [], [$X_LIBS])])
 
264
 
 
265
# Check for XKB extension
 
266
AC_CHECK_HEADER([X11/XKBlib.h],
 
267
  [AC_CHECK_LIB([X11], [XkbQueryExtension],
 
268
    [AC_DEFINE([VINO_HAVE_XKB], [], [Defined if the XKB X extension is present])],
 
269
  [], [$X_LIBS])])
 
270
 
 
271
AC_CHECK_HEADERS([netinet/in.h sys/time.h fcntl.h unistd.h sys/socket.h ifaddrs.h])
 
272
 
 
273
# Check for getifaddrs
 
274
AM_CONDITIONAL([VINO_HAVE_SELF_IFADDRS], [test "x$ac_cv_header_ifaddrs_h" != "xyes"])
 
275
 
 
276
# RFC2553 introduce sockaddr_storage as ifa_addr member in ifaddrs structure
 
277
# Not all distros follow this.
 
278
AS_IF([test "x$ac_cv_header_ifaddrs_h" = "xyes"],
 
279
  [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 
280
    #include <net/if.h>
 
281
    #include <ifaddrs.h>
 
282
    ]], [[
 
283
    struct ifaddrs *myaddrs;
 
284
    getifaddrs (&myaddrs);
 
285
    if (myaddrs->ifa_addr->ss_family == AF_INET) {
 
286
    }
 
287
    ]])],
 
288
    [have_sockaddr_storage=yes],
 
289
    [have_sockaddr_storage=no])],
 
290
  [AS_IF([test "x$have_sockaddr_storage" = "xyes"],
 
291
    [AC_DEFINE([RFC2553], [], [Define if RFC2553 is followed])])])
 
292
 
 
293
AC_C_BIGENDIAN
 
294
AC_C_INLINE
 
295
 
 
296
AC_CHECK_LIB([resolv], [herror])
 
297
AC_SEARCH_LIBS([strerror],[cposix])
 
298
AC_CHECK_FUNCS([gettimeofday])
 
299
 
 
300
# Check for IPv6 support
 
301
AC_MSG_CHECKING([checking for IPv6 support])
 
302
AC_ARG_ENABLE([ipv6],
 
303
  [AS_HELP_STRING([--disable-ipv6],
 
304
    [ignore the presence of IPv6 support and disable it])],
 
305
    [],
 
306
    [enable_ipv6=yes])
 
307
 
 
308
AS_IF([test "x$enable_ipv6" != "xno"],
 
309
  [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 
310
    #include <sys/types.h>
 
311
    #include <sys/socket.h>
 
312
    ]], [[
 
313
      socket(AF_INET6, SOCK_STREAM, 0);
 
314
    ]])],
 
315
    [have_ipv6=yes],
 
316
    [have_ipv6=no])])
 
317
 
 
318
AS_IF([test "x$have_ipv6" = "xyes"],
 
319
  [AC_DEFINE([VINO_ENABLE_IPV6], [], [Define to enable IPv6 support])],
 
320
  [AS_IF([test "x$enable_ipv6" = "xyes"],
 
321
    [AC_MSG_ERROR([IPv6 support requested but not found])])])
 
322
AC_MSG_RESULT([$have_ipv6])
 
323
 
 
324
# GNOME libraries
 
325
GTK_VERSION=3.0.0
 
326
GLIB_VERSION=2.17.0
 
327
GIO_VERSION=2.26
 
328
SOUP_VERSION=2.24.0
 
329
 
 
330
PKG_CHECK_MODULES([VINO_SERVER], [glib-2.0 >= $GLIB_VERSION gio-unix-2.0 gtk+-x11-3.0 >= $GTK_VERSION $TELEPATHY_GLIB_DEPS $LIBNOTIFY_DEPS $GNOME_KEYRING_DEPS $NETWORKMANAGER_DEPS $GNUTLS_DEPS $AVAHI_DEPS])
 
331
 
 
332
PKG_CHECK_MODULES([VINO_CAPPLET], [glib-2.0 >= $GLIB_VERSION gio-2.0 >= $GIO_VERSION gtk+-3.0 >= $GTK_VERSION libsoup-2.4 >= $SOUP_VERSION $GNOME_KEYRING_DEPS])
 
333
 
 
334
PKG_CHECK_MODULES([VINO_TOOLS], [glib-2.0 >= $GLIB_VERSION gio-2.0 >= $GIO_VERSION gobject-2.0 >= $GLIB_VERSION $GNOME_KEYRING_DEPS])
 
335
 
 
336
# EGG stuff
 
337
PKG_CHECK_MODULES([EGG_SMCLIENT], [gtk+-3.0])
 
338
 
 
339
GLIB_GSETTINGS
 
340
 
 
341
AC_CONFIG_FILES([
 
342
Makefile
 
343
capplet/vino-preferences.desktop.in
 
344
po/Makefile.in
 
345
])
 
346
 
 
347
AC_OUTPUT