~ubuntu-branches/ubuntu/saucy/lcmaps-plugins-voms/saucy

                                                                                                                                                             

# Process this file with autoconf to produce a configure script.

 

AC_PREREQ(2.57)

AC_INIT([LCMAPS plugins voms], [1.5.5])

AC_CONFIG_MACRO_DIR([project])

AM_INIT_AUTOMAKE([1.6.3 subdir-objects foreign])

AC_CONFIG_SRCDIR([src/lcmaps_voms_config.h.in])

 

# Notices.

AC_COPYRIGHT([Copyright (c) 2004 The EU EGEE Project

See LICENCE file for details

])

AC_REVISION([$Revision: 1.14 $])

 

#Environment.

WORKDIR=`pwd`

AC_SUBST(WORKDIR)

 

DISTBIN=$WORKDIR/../../dist

AC_SUBST(DISTBIN)

 

# Checks for programs.

AC_PROG_CC

AC_PROG_CXX

AC_PROG_LN_S

AC_PROG_MAKE_SET

AC_PROG_LIBTOOL

AM_PROG_CC_C_O

AC_PROG_INSTALL

 

# Checks for libraries.

AC_CHECK_LIB([crypto], [X509_free])

 

# Checks for header files.

AC_HEADER_DIRENT

AC_HEADER_STDC

AC_CHECK_HEADERS([dlfcn.h malloc.h stdlib.h string.h syslog.h unistd.h utime.h values.h])

 

# Checks for typedefs, structures, and compiler characteristics.

AC_C_CONST

AC_TYPE_SIZE_T

AC_STRUCT_TM

 

# Checks for library functions.

AC_FUNC_CLOSEDIR_VOID

AC_FUNC_MALLOC

AC_FUNC_MEMCMP

AC_FUNC_MKTIME

AC_FUNC_REALLOC

AC_FUNC_STAT

AC_FUNC_UTIME_NULL

AC_CHECK_FUNCS([setenv strchr strcspn strdup strerror strncasecmp strpbrk strspn strstr strtol utime])

 

# Set lcmaps variables

AC_LCMAPS_INTERFACE([basic])

if test "x$have_lcmaps_basic_interface" = "xno" ; then

    AC_MSG_FAILURE(["no LCMAPS basic interface found"])

fi

 

dnl Check for gsi mode

enable_gsi_mode_default=yes

AC_ARG_ENABLE([gsi-mode],

              [AC_HELP_STRING([--enable-gsi-mode],

                [use lcmaps-plugins-voms flavour that uses a GSI interface (default)])],

              [enable_gsi_mode=$enableval],

              [enable_gsi_mode=$enable_gsi_mode_default])

AM_CONDITIONAL(LCMAPS_GSI_MODE, test x$enable_gsi_mode = xyes)

 

if test x$enable_gsi_mode = xyes ; then

    LCMAPS_FLAVOUR=""

    LCMAPS_FLAVOUR_NAME=""

 

    AC_DEFINE(LCMAPS_GSI_MODE, 1, "If defined provide the GSI interface to LCMAPS")

    AC_MSG_RESULT([Creating GSI flavour of LCMAPS])

 

    # Check globus modules

    AC_GLOBUS([CORE],[],AC_MSG_FAILURE(["no globus-core found"]))

 

    AC_GLOBUS([COMMON],[],AC_MSG_FAILURE(["no globus-common found"]))

    AC_GLOBUS([GSI_CALLBACK],[],AC_MSG_FAILURE(["no globus-gsi-callback found"]))

    AC_GLOBUS([GSI_CREDENTIAL],[],AC_MSG_FAILURE(["no globus-gsi-credential found"]))

    AC_GLOBUS([GSI_PROXY_CORE],[],AC_MSG_FAILURE(["no globus-gsi-proxy-core found"]))

    AC_GLOBUS([GSI_PROXY_SSL],[],AC_MSG_FAILURE(["no globus-gsi-proxy-ssl found"]))

    AC_GLOBUS([GSSAPI_GSI],[],AC_MSG_FAILURE(["no globus-gssapi-gsi found"]))

    AC_GLOBUS([GSS_ASSIST],[],AC_MSG_FAILURE(["no globus-gss-assist found"]))

fi

 

# Check voms location

have_voms=no

AC_VOMS([],have_voms=yes,have_voms=no)

AC_MSG_RESULT(["VOMS found $have_voms"])

if test "x$have_voms" = "xno" ; then

    AC_MSG_FAILURE(["no working voms found"])

fi

 

dnl allow the setting of a different path for the plug-ins

dnl Makefiles should set the plugindir to $MODULEDIR.

AC_ARG_WITH([moduledir],

  [AS_HELP_STRING([--with-moduledir=path],

    [Specify the install location of the plug-ins])],

[

        AC_SUBST([MODULEDIR], [$withval])

],

[

        AC_SUBST([MODULEDIR], ['${libdir}/lcmaps'])

])

 

# Defines to be added for cpp (will change)

ADD_THESE_DEFINES="-D ALLOW_EMPTY_CREDENTIALS -D DEBUG_LEVEL=0"

AC_SUBST(ADD_THESE_DEFINES)

 

# Find proper shared library extension

eval SHREXT=$shrext_cmds

AC_SUBST(SHREXT)

 

# Configuration items

AC_CONFIG_HEADERS([src/lcmaps_voms_config.h])

AC_CONFIG_FILES([Makefile])

AC_CONFIG_FILES([doc/Makefile])

AC_CONFIG_FILES([src/Makefile])

AC_CONFIG_FILES([src/voms/Makefile])

AC_CONFIG_FILES([src/gridlist/Makefile])

 

AC_OUTPUT