~unity-team/unity-lens-sample/trunk

AC_INIT(unity-place-sample, 0.1.0, https://launchpad.net/unity-place-sample)

AC_COPYRIGHT([Copyright 2010 Canonical])

 

AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)

 

#####################################################

# Silent build rules

#####################################################

m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])

 

AC_PREREQ(2.59)

 

AC_CONFIG_HEADERS([config.h])

 

#####################################################

# Init the other things we depend on

#####################################################

AM_MAINTAINER_MODE

AM_PROG_VALAC([0.10.0])

AS_IF([test -z "$VALAC"], [AC_MSG_ERROR(["No valac compiler found."])])

AC_PROG_CC

AM_PROG_CC_C_O

AC_HEADER_STDC

 

LT_INIT

AC_CONFIG_MACRO_DIR([m4])

 

#############################################

# Gettext

#############################################

GETTEXT_PACKAGE="$PACKAGE"

AC_SUBST(GETTEXT_PACKAGE)

AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])

AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [gettext domain])

AM_GLIB_GNU_GETTEXT

 

# AM_GNOME_GETTEXT above substs $DATADIRNAME

# this is the directory where the *.{mo,gmo} files are installed

localedir='${prefix}/${DATADIRNAME}/locale'

AC_SUBST(localedir)

 

IT_PROG_INTLTOOL([0.40.0])

 

AC_DEFINE_UNQUOTED(LOCALE_DIR, "${PREFIX}/${DATADIRNAME}/locale",[Locale directory])

AC_DEFINE_UNQUOTED(DATADIR, "${PREFIX}/${DATADIRNAME}",[Data directory])

AC_DEFINE_UNQUOTED(PREFIXDIR, "${PREFIX}",[Prefix directory])

 

######################################################

# intltool rule for generating translated .place file

######################################################

INTLTOOL_PLACE_RULE='%.place: %.place.in $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'

AC_SUBST(INTLTOOL_PLACE_RULE)

 

#####################################################

# Check for module and library dependancies

#####################################################

GLIB_REQUIRED=2.22

PKG_CHECK_MODULES(PLACE_DAEMON,

                  glib-2.0 >= $GLIB_REQUIRED

                  gobject-2.0 >= $GLIB_REQUIRED

                  gio-2.0 >= $GLIB_REQUIRED

                  gio-unix-2.0 >= $GLIB_REQUIRED

                  dbus-glib-1 >= 0.88

                  gee-1.0

                  dee-1.0 >= 0.4.2

                  unity >= 0.2.41)

 

AC_SUBST(PLACE_DAEMON_CFLAGS)

AC_SUBST(PLACE_DAEMON_LIBS)

 

#####################################################

# local install for distcheck and stand-alone running

#####################################################

with_localinstall="no"

AC_ARG_ENABLE(localinstall,

              AS_HELP_STRING([--enable-localinstall],

                             [Install all of the files locally instead of in system directories (for distcheck)]),

              with_localinstall=$enableval,

              with_localinstall=no)

 

AM_CONDITIONAL([HAVE_LOCALINSTALL], [test "x$with_localinstall" = "xyes"])

 

#####################################################

# Expand variables needed for config.vala (see acinclude.m4)

#####################################################

AS_AC_EXPAND(PREFIX, $prefix)

AC_SUBST(PREFIX)

 

AS_AC_EXPAND(DATADIR, $datarootdir)

AC_SUBST(DATADIR)

 

#####################################################

# look for dbus service dir

#####################################################

if test "x$with_localinstall" = "xyes"; then

        DBUSSERVICEDIR="${datadir}/dbus-1/services/"

else

        DBUSSERVICEDIR=`$PKG_CONFIG --variable=session_bus_services_dir dbus-1`

fi

AC_SUBST(DBUSSERVICEDIR)

 

#####################################################

# Create the Makefiles

#####################################################

AC_CONFIG_FILES([

  Makefile

  sample.place.in

  data/Makefile

  src/Makefile

  src/config.vala

  po/Makefile.in

])

AC_OUTPUT

 

#####################################################

# Output the results

#####################################################

AC_MSG_NOTICE([

 

  Unity Sample Place Daemon $VERSION

  -------------------------------

 

  Prefix         : ${prefix}

  

  Local install  : ${with_localinstall}

 

  Extra CFlags   : ${CPPFLAGS} $MAINTAINER_CFLAGS

  Extra ValaFlags: ${CPPFLAGS} $MAINTAINER_VALAFLAGS

])