~extremepopcorn/dhlib/dhlib_ep

/* <license>

 * This file is part of the dis-Emi-A HaXe Library. Copyright (c) edA-qa mort-ora-y

 * For full copyright and license information please refer to doc/license.txt.

 * </license> 

 */

package flashx;

 

import flash.display.DisplayObject;

import flash.display.BitmapData;

 

/**

 * This provides a way to erase the form of one sprite from another one...

 *

 * This is just an attempt to workaround the circus of shitty Flash APIs, a true carneval

 * of nonsense:

 * 1. erase mode doesn't erase everything (see FlashDefectErase)

 * 2. an object without a parent has an odd transform (scaled 5 on my test)

 * 3. the stage's children during startup/resize have an incorrect (likely previous) transform

 */

class Eraser

{

        var alpha : Float;      //any alpha above this is considered to be part of eraser in provided sprite

        

        var objx : RenderCache;

        

        public function new( alpha : Null<Float> )

        {

                this.alpha = (alpha == null) ? 0.5 : alpha;

                

                objx = new RenderCache();

                objx.useFilters = false;

        }

        

        /**

         * For any pixel in "what" which has an alpha >= to ctor alpha the corresponding

         * pixel in from is set to 0 (color is not preserved in this version)

         *

         * @param       what    [in] the stencil form to erase

         * @param       from    [in] from where to erase "what"

         */

        public function fullErase( what : DisplayObject, from : BitmapData )

        {

                //This is what doesn't work correclt (see FlashDefectErase)

                //from.draw( what, null, null, flash.display.BlendMode.ERASE );

                

                //if parent is null then the transform space is undefined (and unusual in Flash, not simply neutral)

                //changing mind, if there is a translation space it is likely wrong, espeically on startup or

                //during a resize.  We will rather here draw without a transform matrix, and thus not support

                //sprites in the display list (we'll assume they are already confined to the bitmap)

                Assert.isNull( what.parent );

                

                //translate to a null space gives the native coords

                var bound = what.getBounds( null );

                //only do the parts which intersect

                var rect = from.rect.intersection( bound );

                

                //we need these a lot

                var top = Math.floor( rect.top );

                var left = Math.floor( rect.left );

                var alphaInt : Int = Math.floor( alpha * 255 ); //Note: *NOT* 256, since max is 0xFF !

                

                //create the rendering form of "what"

                var clip = objx.renderBitmap( what, rect, false, true );

                

#if false // Inefficient but clear method //also the form needed if color is to be preserved...

                //iterate through "what" space

                for( y in 0...Math.floor(rect.height) )

                        for( x in 0...Math.floor(rect.width) )

                        {

                                var cc = clip.getPixel32( x, y );

                                if( cc >> 24 & 0xFF >= alphaInt )       //we can't optimize this to avoid shifting, since haXe Int is signed, and the high-alpha bit changes the sign :(

                                        from.setPixel32( x + left, y + top, 0 );        //ignore color for now...

                        }

#else

                //use Flash threshhold function (should be faster, but no option to preserve color)

                from.threshold( clip, 

                        new flash.geom.Rectangle( 0, 0, rect.width, rect.height ),

                        new flash.geom.Point( rect.left, rect.top ),

                        ">=",   alphaInt << 24,

                        0x00000000,     //new color

                        0xFF000000,     //mask

                        false );

#end                    

        }

}