← Back to branch summary

~ubuntu-branches/ubuntu/saucy/merkaartor/saucy

« back to all changes in this revision

Viewing changes to src/src.pro

  • Committer: Bazaar Package Importer
  • Author(s): Bernd Zeimetz
  • Date: 2009-09-13 00:52:12 UTC
  • mto: (1.2.7 upstream) (0.1.3 upstream) (3.1.7 sid)
  • mto: This revision was merged to the branch mainline in revision 10.
  • Revision ID: james.westby@ubuntu.com-20090913005212-pjecal8zxm07x0fj
Import upstream version 0.14+svnfixes~20090912

Show diffs side-by-side

added added

removed removed

Lines of Context:
src/src.pro
 
1
# external supported variables:
 
2
# passed on commandline like "qmake NOWEBKIT=1"
 
3
# TRANSDIR_MERKAARTOR - translations directory for merkaartor
 
4
# TRANSDIR_SYSTEM     - translations directory for Qt itself
 
5
# OUTPUT_DIR          - base directory for local output files
 
6
# PREFIX              - base prefix for installation (default: /usr/local)
 
7
# LIBDIR              - base directory for plugins (default: $$PREFIX/lib)
 
8
# NODEBUG             - no debug target
 
9
# OSMARENDER          - enable osmarender
 
10
# GDAL                - enable GDAL
 
11
# MOBILE              - enable MOBILE
 
12
# GEOIMAGE            - enable geotagged images (needs exiv2)
 
13
# GPSD                - use gpsd as location provider
 
14
# NVIDIA_HACK         - used to solve nvidia specific slowdown
 
15
# FORCE_CUSTOM_STYLE  - force custom style (recommended on Linux until the "expanding dock" is solved upstream)
 
16
# THREADED_BROWSERIMAGEMANAGER
 
17
 
 
18
#Static config
 
19
include (Config.pri)
 
20
 
 
21
#Custom config
 
22
include(Custom.pri)
 
23
 
 
24
#Qt Version
 
25
QT_VERSION = $$[QT_VERSION]
 
26
QT_VERSION = $$split(QT_VERSION, ".")
 
27
QT_VER_MAJ = $$member(QT_VERSION, 0)
 
28
QT_VER_MIN = $$member(QT_VERSION, 1)
 
29
 
 
30
DEFINES += VERSION=$$VERSION
 
31
DEFINES += REVISION=$$REVISION
 
32
 
 
33
TEMPLATE = app
 
34
TARGET = merkaartor
 
35
 
 
36
CONFIG += rtti stl 
 
37
#CONFIG -= exceptions
 
38
QT += svg network xml core gui
 
39
 
 
40
!contains(NODEBUG,1) {
 
41
    CONFIG += debug
 
42
    #OBJECTS_DIR += $$PWD/../tmp/$$(QMAKESPEC)/obj_debug
 
43
}
 
44
contains(NODEBUG,1) {
 
45
    CONFIG += release
 
46
    DEFINES += NDEBUG
 
47
    #OBJECTS_DIR += $$PWD/../tmp/$$(QMAKESPEC)/obj_release
 
48
}
 
49
COMMON_DIR=$$PWD/../binaries
 
50
OUTPUT_DIR=$$PWD/../binaries/$$(QMAKESPEC)
 
51
DESTDIR = $$OUTPUT_DIR/bin
 
52
 
 
53
#UI_DIR += $$PWD/../tmp/$$(QMAKESPEC)
 
54
#MOC_DIR += $$PWD/../tmp/$$(QMAKESPEC)
 
55
#RCC_DIR += $$PWD/../tmp/$$(QMAKESPEC)
 
56
 
 
57
INCLUDEPATH += $$PWD/../include $$PWD/../interfaces
 
58
DEPENDPATH += $$PWD/../interfaces
 
59
 
 
60
win32 {
 
61
        INCLUDEPATH += $$COMMON_DIR/include
 
62
        LIBS += -L$$COMMON_DIR/lib
 
63
        RC_FILE = $$PWD/../Icons/merkaartor-win32.rc
 
64
}
 
65
 
 
66
contains(GPSD,1) {
 
67
    DEFINES += USEGPSD
 
68
}
 
69
 
 
70
contains(FORCE_CUSTOM_STYLE,1) {
 
71
    DEFINES += FORCED_CUSTOM_STYLE
 
72
}
 
73
 
 
74
contains(NVIDIA_HACK,1) {
 
75
    DEFINES += ENABLE_NVIDIA_HACK
 
76
}
 
77
 
 
78
INCLUDEPATH += $$PWD Render qextserialport GPS NameFinder
 
79
DEPENDPATH += $$PWD Render qextserialport GPS NameFinder
 
80
 
 
81
!contains(NOUSEWEBKIT,1) {
 
82
        greaterThan(QT_VER_MAJ, 3) : greaterThan(QT_VER_MIN, 3) {
 
83
        DEFINES += USE_WEBKIT
 
84
        SOURCES += QMapControl/browserimagemanager.cpp
 
85
        HEADERS += QMapControl/browserimagemanager.h
 
86
        QT += webkit
 
87
        contains(THREADED_BROWSERIMAGEMANAGER,1): DEFINES += BROWSERIMAGEMANAGER_IS_THREADED
 
88
        }
 
89
}
 
90
 
 
91
TRANSLATIONS += \
 
92
        ../translations/merkaartor_ar.ts \
 
93
        ../translations/merkaartor_cs.ts \
 
94
        ../translations/merkaartor_de.ts \
 
95
        ../translations/merkaartor_es.ts \
 
96
        ../translations/merkaartor_fr.ts \
 
97
        ../translations/merkaartor_it.ts \
 
98
        ../translations/merkaartor_ja.ts \
 
99
        ../translations/merkaartor_nl.ts \
 
100
        ../translations/merkaartor_pl.ts \
 
101
        ../translations/merkaartor_ru.ts \
 
102
        ../translations/merkaartor_sv.ts
 
103
 
 
104
BINTRANSLATIONS += \
 
105
        ../translations/merkaartor_ar.qm \
 
106
        ../translations/merkaartor_cs.qm \
 
107
        ../translations/merkaartor_de.qm \
 
108
        ../translations/merkaartor_es.qm \
 
109
        ../translations/merkaartor_fr.qm \
 
110
        ../translations/merkaartor_it.qm \
 
111
        ../translations/merkaartor_ja.qm \
 
112
        ../translations/merkaartor_nl.qm \
 
113
        ../translations/merkaartor_pl.qm \
 
114
        ../translations/merkaartor_ru.qm \
 
115
        ../translations/merkaartor_sv.qm
 
116
 
 
117
#Include file(s)
 
118
include(Merkaartor.pri)
 
119
include(QMapControl.pri)
 
120
include(ImportExport.pri)
 
121
include(Render/Render.pri)
 
122
!symbian:include(qextserialport/qextserialport.pri)
 
123
include(GPS/GPS.pri)
 
124
include(Tools/Tools.pri)
 
125
include(TagTemplate/TagTemplate.pri)
 
126
include(NameFinder/NameFinder.pri)
 
127
 
 
128
 
 
129
!win32 {
 
130
    # Prefix: base instalation directory
 
131
    isEmpty( PREFIX ) {
 
132
                PREFIX = /usr/local
 
133
        }
 
134
    isEmpty( LIBDIR ) {
 
135
                LIBDIR = $${PREFIX}/lib${LIB_SUFFIX}
 
136
        }
 
137
        DEFINES += PLUGINS_DIR=$${LIBDIR}/merkaartor/plugins
 
138
    target.path = $${PREFIX}/bin
 
139
    SHARE_DIR = $${PREFIX}/share/merkaartor
 
140
 
 
141
    isEmpty(TRANSDIR_MERKAARTOR) {
 
142
        TRANSDIR_MERKAARTOR = $${SHARE_DIR}/translations
 
143
    }
 
144
}
 
145
win32 {
 
146
        DEFINES += PLUGINS_DIR=plugins
 
147
    SHARE_DIR = share
 
148
    isEmpty(TRANSDIR_MERKAARTOR) {
 
149
        TRANSDIR_MERKAARTOR = translations
 
150
    }
 
151
    isEmpty(TRANSDIR_SYSTEM) {
 
152
        TRANSDIR_SYSTEM = translations
 
153
    }
 
154
}
 
155
 
 
156
DEFINES += SHARE_DIR=$${SHARE_DIR}
 
157
INSTALLS += target
 
158
 
 
159
win32-msvc* {
 
160
    DEFINES += _USE_MATH_DEFINES
 
161
}
 
162
 
 
163
 
 
164
count(TRANSDIR_MERKAARTOR, 1) {
 
165
        translations.path =  $${TRANSDIR_MERKAARTOR}
 
166
        translations.files = $${BINTRANSLATIONS}
 
167
        DEFINES += TRANSDIR_MERKAARTOR=$$translations.path
 
168
        INSTALLS += translations
 
169
}
 
170
 
 
171
count(TRANSDIR_SYSTEM, 1) {
 
172
        DEFINES += TRANSDIR_SYSTEM=$${TRANSDIR_SYSTEM}
 
173
}
 
174
 
 
175
contains(MOBILE,1) {
 
176
    DEFINES += _MOBILE
 
177
    win32-wince* {
 
178
      DEFINES += _WINCE
 
179
    }
 
180
}
 
181
 
 
182
contains(GEOIMAGE, 1) {
 
183
        DEFINES += GEOIMAGE
 
184
        LIBS += -lexiv2
 
185
        include(GeoImage.pri)
 
186
}
 
187
 
 
188
lists.path = $${SHARE_DIR}
 
189
lists.files = \ 
 
190
    $$PWD/../share/BookmarksList.xml \
 
191
    $$PWD/../share/Projections.xml \
 
192
    $$PWD/../share/WmsServersList.xml \
 
193
    $$PWD/../share/TmsServersList.xml
 
194
INSTALLS += lists
 
195
 
 
196
contains (GDAL, 1) {
 
197
        DEFINES += USE_GDAL
 
198
        win32 {
 
199
                win32-msvc*:LIBS += -lgdal_i
 
200
                win32-g++:LIBS += -lgdal
 
201
        }
 
202
        unix {
 
203
                INCLUDEPATH += /usr/include/gdal
 
204
                LIBS += -lgdal
 
205
        }
 
206
}
 
207
world_shp.path = $${SHARE_DIR}
 
208
world_shp.files = $$PWD/../share/world_background.osb
 
209
 
 
210
DEFINES += WORLD_SHP=$$world_shp.path/world_background.osb
 
211
INSTALLS += world_shp
 
212
 
 
213
desktop.path = $${PREFIX}/share/applications
 
214
desktop.files = merkaartor.desktop
 
215
desktopicons.path = $${PREFIX}/share/icons/hicolor/48x48/apps/
 
216
desktopicons.files = $$PWD/../Icons/48x48/merkaartor.png
 
217
INSTALLS += desktop desktopicons
 
218
 
 
219