~ubuntu-branches/ubuntu/raring/mumble/raring

HEADERS *= BanEditor.h ACLEditor.h ConfigWidget.h Log.h AudioConfigDialog.h AudioStats.h AudioInput.h AudioOutput.h CustomElements.h MainWindow.h ServerHandler.h About.h ConnectDialog.h GlobalShortcut.h TextToSpeech.h Settings.h Database.h VersionCheck.h Global.h UserModel.h Audio.h ConfigDialog.h Plugins.h LookConfig.h Overlay.h SharedMemory.h AudioWizard.h ViewCert.h TextMessage.h NetworkConfig.h LCD.h Usage.h Cert.h ClientUser.h UserEdit.h Tokens.h UserView.h RichTextEditor.h UserInformation.h FileEngine.h SocketRPC.h

SOURCES *= BanEditor.cpp ACLEditor.cpp ConfigWidget.cpp Log.cpp AudioConfigDialog.cpp AudioStats.cpp AudioInput.cpp AudioOutput.cpp main.cpp CustomElements.cpp MainWindow.cpp ServerHandler.cpp About.cpp ConnectDialog.cpp Settings.cpp Database.cpp VersionCheck.cpp Global.cpp UserModel.cpp Audio.cpp ConfigDialog.cpp Plugins.cpp LookConfig.cpp Overlay.cpp SharedMemory.cpp AudioWizard.cpp ViewCert.cpp Messages.cpp TextMessage.cpp GlobalShortcut.cpp NetworkConfig.cpp LCD.cpp Usage.cpp Cert.cpp ClientUser.cpp UserEdit.cpp Tokens.cpp UserView.cpp RichTextEditor.cpp UserInformation.cpp FileEngine.cpp SocketRPC.cpp

SOURCES *= smallft.cpp

DIST *= ../../icons/mumble.ico licenses.h smallft.h ../../icons/mumble.xpm murmur_pch.h mumble.plist

RESOURCES *= mumble.qrc mumble_flags.qrc

FORMS *= ConfigDialog.ui MainWindow.ui ConnectDialog.ui ConnectDialogEdit.ui BanEditor.ui ACLEditor.ui Plugins.ui Overlay.ui LookConfig.ui AudioInput.ui AudioOutput.ui Log.ui TextMessage.ui AudioStats.ui NetworkConfig.ui LCD.ui GlobalShortcut.ui GlobalShortcutTarget.ui Cert.ui UserEdit.ui AudioWizard.ui Tokens.ui RichTextEditor.ui RichTextEditorLink.ui UserInformation.ui

TRANSLATIONS = mumble_en.ts mumble_es.ts mumble_de.ts mumble_fr.ts mumble_pl.ts mumble_ru.ts mumble_cs.ts mumble_it.ts mumble_ja.ts mumble_zh_CN.ts mumble_zh_TW.ts mumble_da.ts

PRECOMPILED_HEADER = mumble_pch.hpp

INCLUDEPATH *= ../bonjour

isEmpty(QMAKE_LRELEASE) {

QMAKE_QMAKE_BASE = $$basename(QMAKE_QMAKE)

QMAKE_LRELEASE = $$dirname(QMAKE_QMAKE)/$$replace(QMAKE_QMAKE_BASE,qmake,lrelease)

}

unix:!CONFIG(bundled-speex):system(pkg-config --atleast-version=1.2 speexdsp) {

CONFIG *= no-bundled-speex

}

CONFIG(no-crash-report) {

DEFINES *= NO_CRASH_REPORT

} else {

HEADERS *= CrashReporter.h

SOURCES *= CrashReporter.cpp

}

CONFIG(no-bundled-speex) {

PKGCONFIG *= speex speexdsp

}

!CONFIG(no-bundled-speex) {

INCLUDEPATH *= ../../speex/include ../../speex/libspeex ../../speexbuild

LIBS *= -lspeex

}

unix:!CONFIG(bundled-celt):system(pkg-config --atleast-version=0.7.0 celt) {

CONFIG *= no-bundled-celt

}

CONFIG(no-bundled-celt) {

INCLUDEPATH *= /usr/include/celt

}

!CONFIG(no-bundled-celt) {

INCLUDEPATH *= ../../celt-0.7.0-src/libcelt

}

!win32 {

QMAKE_CXXFLAGS *= -Wall -Wextra

}

!win32:!CONFIG(no-dbus) {

CONFIG *= dbus

}

!CONFIG(no-g15) {

CONFIG *= g15

}

!CONFIG(no-bonjour) {

CONFIG *= bonjour

}

win32 {

RC_FILE = mumble.rc

HEADERS *= GlobalShortcut_win.h TaskList.h

SOURCES *= GlobalShortcut_win.cpp TextToSpeech_win.cpp Overlay_win.cpp SharedMemory_win.cpp os_win.cpp TaskList.cpp

LIBS *= -l"$$(DXSDK_DIR)Lib/x86/dxguid" -l"$$(DXSDK_DIR)Lib/x86/dinput8" -lsapi -lole32 -lws2_32 -ladvapi32 -lwintrust -ldbghelp -llibsndfile-1 -lshell32 -lshlwapi

LIBS *= -ldelayimp -delayload:speex.dll -delayload:shell32.dll

DEFINES *= WIN32

!CONFIG(no-asio) {

CONFIG *= asio

}

!CONFIG(no-directsound) {

CONFIG *= directsound

}

!CONFIG(no-wasapi) {

CONFIG *= wasapi

}

CONFIG(release, debug|release) {

QMAKE_LFLAGS *= /MANIFESTUAC:\"level=\'asInvoker\' uiAccess=\'true\'\"

}

unix {

HAVE_PULSEAUDIO=$$system(pkg-config --modversion --silence-errors libpulse)

HAVE_PORTAUDIO=$$system(pkg-config --modversion --silence-errors portaudio-2.0)

!isEmpty(HAVE_PORTAUDIO):!CONFIG(no-portaudio) {

CONFIG *= portaudio

}

100

101

!isEmpty(HAVE_PULSEAUDIO):!CONFIG(no-pulseaudio) {

102

CONFIG -= portaudio

103

CONFIG *= pulseaudio

104

}

105

106

!CONFIG(no-bundled-speex) {

107

QMAKE_CFLAGS *= -I../../speex/include -I../../speexbuild

108

QMAKE_CXXFLAGS *= -I../../speex/include -I../../speexbuild

109

QMAKE_CXXFLAGS_RELEASE *= -I../../speex/include -I../../speexbuild

110

QMAKE_CXXFLAGS_DEBUG *= -I../../speex/include -I../../speexbuild

111

}

112

113

CONFIG *= link_pkgconfig

114

115

PKGCONFIG *= openssl sndfile

116

117

contains(UNAME, Linux) {

118

!CONFIG(no-oss) {

119

CONFIG *= oss

120

}

121

122

!CONFIG(no-alsa) {

123

CONFIG *= alsa

124

}

125

126

!CONFIG(no-speechd) {

127

CONFIG *= speechd

128

}

129

130

HEADERS *= GlobalShortcut_unix.h

131

SOURCES *= GlobalShortcut_unix.cpp TextToSpeech_unix.cpp Overlay_unix.cpp SharedMemory_unix.cpp

132

LIBS *= -lrt

133

}

134

135

!macx {

136

PKGCONFIG *= x11

137

LIBS *= -lXi

138

}

139

140

macx {

141

TARGET = Mumble

142

ICON = ../../icons/mumble.icns

143

QMAKE_INFO_PLIST = mumble.plist

144

QMAKE_PKGINFO_TYPEINFO = MBLE

145

146

LIBS += -framework Security

147

148

HEADERS *= GlobalShortcut_macx.h ConfigDialogDelegate.h

149

SOURCES *= TextToSpeech_macx.cpp Overlay_unix.cpp SharedMemory_unix.cpp GlobalShortcut_macx.cpp os_macx.cpp

150

151

!CONFIG(no-cocoa) {

152

SOURCES -= ConfigDialog.cpp

153

SOURCES += ConfigDialog.mm ConfigDialogDelegate.mm

154

}

155

156

# CoreAudio

157

LIBS += -framework CoreAudio -framework AudioUnit -framework AudioToolbox

158

SOURCES += CoreAudio.cpp

159

HEADERS += CoreAudio.h

160

}

161

}

162

163

alsa {

164

DEFINES *= USE_ALSA

165

PKGCONFIG *= alsa

166

HEADERS *= ALSAAudio.h

167

SOURCES *= ALSAAudio.cpp

168

}

169

170

oss {

171

DEFINES *= USE_OSS

172

HEADERS *= OSS.h

173

SOURCES *= OSS.cpp

174

INCLUDEPATH *= /usr/lib/oss/include

175

}

176

177

pulseaudio {

178

DEFINES *= USE_PULSEAUDIO

179

PKGCONFIG *= libpulse

180

HEADERS *= PulseAudio.h

181

SOURCES *= PulseAudio.cpp

182

}

183

184

portaudio {

185

DEFINES *= USE_PORTAUDIO

186

PKGCONFIG *= portaudio-2.0

187

HEADERS *= PAAudio.h

188

SOURCES *= PAAudio.cpp

189

}

190

191

asio {

192

DEFINES *= USE_ASIO

193

HEADERS *= ASIOInput.h

194

SOURCES *= ASIOInput.cpp

195

FORMS *= ASIOInput.ui

196

INCLUDEPATH *= ../../asio/common ../../asio/host ../../asio/host/pc

197

}

198

199

bonjour {

200

DEFINES *= USE_BONJOUR

201

202

HEADERS *= ../bonjour/bonjourrecord.h ../bonjour/bonjourserviceresolver.h ../bonjour/bonjourservicebrowser.h BonjourClient.h

203

SOURCES *= ../bonjour/bonjourserviceresolver.cpp ../bonjour/bonjourservicebrowser.cpp BonjourClient.cpp

204

win32 {

205

INCLUDEPATH *= /dev/Bonjour/include

206

LIBPATH *= /dev/Bonjour/lib/win32

207

LIBS *= -lDNSSD -delayload:DNSSD.DLL

208

}

209

unix:!macx {

210

system(pkg-config --exists avahi-compat-libdns_sd avahi-client) {

211

PKGCONFIG *= avahi-compat-libdns_sd avahi-client

212

} else {

213

LIBS *= -ldns_sd

214

}

215

}

216

}

217

218

dbus {

219

DEFINES *= USE_DBUS

220

CONFIG *= qdbus

221

HEADERS *= DBus.h

222

SOURCES *= DBus.cpp

223

}

224

225

speechd {

226

DEFINES *= USE_SPEECHD

227

LIBS *= -lspeechd

228

}

229

230

directsound {

231

DEFINES *= USE_DIRECTSOUND

232

HEADERS *= DirectSound.h

233

SOURCES *= DirectSound.cpp

234

LIBS *= -ldsound

235

}

236

237

wasapi {

238

DEFINES *= USE_WASAPI

239

HEADERS *= WASAPI.h

240

SOURCES *= WASAPI.cpp

241

LIBS *= -lAVRT -delayload:AVRT.DLL

242

}

243

244

g15 {

245

DEFINES *= USE_G15

246

unix:!macx {

247

SOURCES *= G15LCDEngine_unix.cpp

248

HEADERS *= G15LCDEngine_unix.h

249

LIBS *= -lg15daemon_client

250

} else {

251

SOURCES *= G15LCDEngine_lglcd.cpp

252

HEADERS *= G15LCDEngine_lglcd.h ../../g15helper/g15helper.h

253

}

254

}

255

256

CONFIG(no-update) {

257

DEFINES *= NO_UPDATE_CHECK

258

}

259

260

!CONFIG(no-embed-qt-translations) {

261

QT_TRANSDIR = $$[QT_INSTALL_TRANSLATIONS]/

262

QT_TRANSDIR = $$replace(QT_TRANSDIR,/,$${DIR_SEPARATOR})

263

264

QT_TRANSLATION_FILES *= qt_de.qm qt_es.qm qt_fr.qm qt_ru.qm qt_pl.qm qt_ja_JP.qm qt_zh_CN.qm qt_zh_TW.qm

265

266

copytrans.output = ${QMAKE_FILE_NAME}

267

copytrans.commands = $$QMAKE_COPY $${QT_TRANSDIR}${QMAKE_FILE_NAME} ${QMAKE_FILE_OUT}

268

copytrans.input = QT_TRANSLATION_FILES

269

copytrans.CONFIG *= no_link target_predeps

270

271

QMAKE_EXTRA_COMPILERS *= copytrans

272

273

RESOURCES *= mumble_qt.qrc

274

}

275

276

!CONFIG(no-embed-tango-icons) {

277

RESOURCES *= mumble_tango.qrc

278

}

279

280

lrel.output = ${QMAKE_FILE_BASE}.qm

281

lrel.commands = $${QMAKE_LRELEASE} ${QMAKE_FILE_NAME}

282

lrel.input = TRANSLATIONS

283

lrel.CONFIG *= no_link target_predeps

284

285

QMAKE_EXTRA_COMPILERS *= lrel

286

287

include(../../symbols.pri)

Older »