← Back to branch summary

~ubuntu-branches/ubuntu/wily/qtbase-opensource-src/wily

« back to all changes in this revision

Viewing changes to mkspecs/features/qt_example_installs.prf

  • Committer: Package Import Robot
  • Author(s): Timo Jyrinki
  • Date: 2013-02-05 12:46:17 UTC
  • Revision ID: package-import@ubuntu.com-20130205124617-c8jouts182j002fx
Tags: upstream-5.0.1+dfsg
Import upstream version 5.0.1+dfsg

Show diffs side-by-side

added added

removed removed

Lines of Context:
mkspecs/features/qt_example_installs.prf
 
1
#
 
2
#  W A R N I N G
 
3
#  -------------
 
4
#
 
5
# This file is not part of the Qt API.  It exists purely as an
 
6
# implementation detail.  It may change from version to version
 
7
# without notice, or even be removed.
 
8
#
 
9
# We mean it.
 
10
#
 
11
 
 
12
probase = $$relative_path($$_PRO_FILE_PWD_, $$dirname(_QMAKE_CONF_)/examples)
 
13
!isEmpty(probase):!contains(probase, ^\\..*) {
 
14
    for(ex, EXAMPLE_FILES): \
 
15
        sourcefiles += $$files($$absolute_path($$ex, $$_PRO_FILE_PWD_))
 
16
    for(res, RESOURCES) {
 
17
        rfile = $$cat($$absolute_path($$res, $$_PRO_FILE_PWD_), lines)
 
18
        for(rline, rfile) {
 
19
            resrc = $$replace(rline, ^[ \\t]*<file[^>]*>([^<]+)</file>[ \\t]*$, \\1)
 
20
            !equals(resrc, $$rline): \
 
21
                sourcefiles += $$resrc
 
22
        }
 
23
    }
 
24
    for(res, RC_FILE) {
 
25
        rfile = $$cat($$absolute_path($$res, $$_PRO_FILE_PWD_), lines)
 
26
        for(rline, rfile) {
 
27
            resrc = $$replace(rline, "^\\d+\\s+ICON\\s+[^\"]*\"([^\"]+)\"\$", \\1)
 
28
            !equals(resrc, $$rline): \
 
29
                sourcefiles += $$resrc
 
30
        }
 
31
    }
 
32
    extras = \
 
33
        $$_PRO_FILE_PWD_/README \
 
34
        $$files($$_PRO_FILE_PWD_/*.pri) \
 
35
        $$replace(_PRO_FILE_, \\.pro$, .qmlproject) \
 
36
        $$replace(_PRO_FILE_, \\.pro$, .json) \
 
37
        $$replace(_PRO_FILE_, \\.pro$, .inf)
 
38
    for(extra, extras): \
 
39
        exists($$extra): \
 
40
            sourcefiles += $$extra
 
41
 
 
42
    # Just for Qt Creator
 
43
    OTHER_FILES += $$sourcefiles
 
44
 
 
45
    for(inst, INSTALLS): \
 
46
        !equals(inst, target):!contains($${inst}.CONFIG, no_check_exist): \
 
47
            for(file, $${inst}.files): \
 
48
                sourcefiles += $$files($$absolute_path($$file, $$_PRO_FILE_PWD_))
 
49
    sourcefiles += \
 
50
        $$_PRO_FILE_ $$RC_FILE $$DEF_FILE \
 
51
        $$SOURCES $$HEADERS $$FORMS $$RESOURCES $$TRANSLATIONS \
 
52
        $$DBUS_ADAPTORS $$DBUS_INTERFACES
 
53
    for(sf, sourcefiles) {
 
54
        sf = $$relative_path($$sf, $$_PRO_FILE_PWD_)
 
55
        contains(sf, \\..*) {
 
56
            check_examples: message("Notice: $$_PRO_FILE_ refers to $$sf")
 
57
        } else {
 
58
            sfp = $$replace(sf, /.*, )
 
59
            !equals(sfp, $$sf): \
 
60
                sources.files *= $$sfp
 
61
            else: \
 
62
                sources.files += $$sf
 
63
        }
 
64
    }
 
65
    sources.path = $$[QT_INSTALL_EXAMPLES]/$$probase
 
66
    INSTALLS += sources
 
67
 
 
68
    check_examples {
 
69
        thefiles = $$files($$_PRO_FILE_PWD_/*)
 
70
        for(i, thefiles): \
 
71
            allfiles += $$relative_path($$i, $$_PRO_FILE_PWD_)
 
72
        for(i, sources.files): \
 
73
            allfiles -= $$relative_path($$i, $$_PRO_FILE_PWD_)
 
74
        for(i, SUBDIRS) {
 
75
            sd = $$eval($${i}.file)
 
76
            !isEmpty(sd) {
 
77
                sd ~= s,/.*,,
 
78
            } else {
 
79
                sd = $$eval($${i}.subdir)
 
80
                isEmpty(sd): sd = $$i
 
81
            }
 
82
            allfiles -= $$sd
 
83
        }
 
84
        allfiles -= doc
 
85
        !isEmpty(allfiles): warning("remaining files in $$_PRO_FILE_PWD_: $$allfiles")
 
86
    }
 
87
}